如何让这个 AppleScript Folder Watch 忽略隐藏的项目？

Question

我几乎整个星期天都在试图找到这个问题的答案，现在我承认失败并寻求你的帮助。我在这里和其他一些 AppleScript 网站上阅读了几个示例，但在应用于此脚本时，它们似乎都不起作用。然而，我确实把这个归结为我。

我正在尝试使用下面的脚本来监视一个文件夹，然后在添加新项目时给我发送一封电子邮件并且它工作正常。我遇到的问题是让它忽略系统[或隐藏]文件夹。

我已经放弃了这样做的努力，因为他们一直在破坏整个事情，所以下面的版本可以工作，但目前它会包含隐藏的项目。

property theName : "Name"
property theAddress : "name@company.com"


on adding folder items to this_folder after receiving added_items
    set added_Items_List to {}
    repeat with oneItem in added_items
        set end of added_Items_List to name of (info for oneItem)
    end repeat
    set {TID, text item delimiters} to {text item delimiters, ", "}
    set added_Items_List to added_Items_List as text
    set text item delimiters to TID
    set dateString to (current date) as string
    set theBody to "There are new files in the FTP folder " & name of (info for this_folder) & ":" & return & return & added_Items_List
    tell application "Mail"
        set newMessage to make new outgoing message with properties {visible:true, subject:"New submissions on FTP: " & dateString, content:theBody}
        tell newMessage
            make new to recipient at end of to recipients with properties {name:theName, address:theAddress}
        end tell
        activate
        send newMessage
    end tell
end adding folder items to

我们将不胜感激任何帮助或指导，希望其他人能从可行的解决方案中受益。

对于遇到此 post 类似问题的任何人，您可能会在其中一个 post 中找到问题的答案。

Applescript System Events Returns .DS_Store - How can I ignore
How to I tell this Applescript to skip some files?

Answer 1

隐藏文件以点开头，只过滤那些项目

on adding folder items to this_folder after receiving added_items
set added_Items_List to {}
repeat with oneItem in added_items
    set fileName to name of (info for oneItem)
    if fileName does not start with "." then
         set end of added_Items_List to fileName
    end if
end repeat
if (count added_Items_List) = 0 then return
....

但是，如果您计算机上的 Finder 不默认显示隐藏文件，则您不需要额外的行。

如何让这个 AppleScript Folder Watch 忽略隐藏的项目？

How do I make this AppleScript Folder Watch ignore hidden items?

email

macos

applescript

osx-yosemite