Jenkins 管道构建失败后如何发送 Slack 通知？

Question

我在 Jenkins v2.19 中有一个管道 groovy 脚本。我还有一个
"Slack Notification Plugin" v2.0.1 和 "Groovy Postbuild Plugin".

我已成功发送消息 "build started" 和 "build finished"（如果有的话）。

当某些构建步骤失败时 – 如何向 Slack 频道发送消息"Build failed"？

Answer 1

您可以这样做并使用 try catch 块。

这是一些示例代码：

node {
    try {
        notifyBuild('STARTED')

        stage('Prepare code') {
            echo 'do checkout stuff'
        }

        stage('Testing') {
            echo 'Testing'
            echo 'Testing - publish coverage results'
        }

        stage('Staging') {
            echo 'Deploy Stage'
        }

        stage('Deploy') {
            echo 'Deploy - Backend'
            echo 'Deploy - Frontend'
        }

  } catch (e) {
    // If there was an exception thrown, the build failed
    currentBuild.result = "FAILED"
    throw e
  } finally {
    // Success or failure, always send notifications
    notifyBuild(currentBuild.result)
  }
}

def notifyBuild(String buildStatus = 'STARTED') {
  // build status of null means successful
  buildStatus =  buildStatus ?: 'SUCCESSFUL'

  // Default values
  def colorName = 'RED'
  def colorCode = '#FF0000'
  def subject = "${buildStatus}: Job '${env.JOB_NAME} [${env.BUILD_NUMBER}]'"
  def summary = "${subject} (${env.BUILD_URL})"

  // Override default values based on build status
  if (buildStatus == 'STARTED') {
    color = 'YELLOW'
    colorCode = '#FFFF00'
  } else if (buildStatus == 'SUCCESSFUL') {
    color = 'GREEN'
    colorCode = '#00FF00'
  } else {
    color = 'RED'
    colorCode = '#FF0000'
  }

  // Send notifications
  slackSend (color: colorCode, message: summary)
}

可以在此处找到完整的代码段 Jenkinsfile Template

Answer 2

基于Liam Newman's blog post, have a look at this cleaned up snippet for Slack only in scripted pipelines (declarative pipeline users scroll down). It uses original Jenkins results, message formatting, better colors (based on EclEmma), and some Groovy features like default arguments：

def notifySlack(String buildStatus = 'STARTED') {
    // Build status of null means success.
    buildStatus = buildStatus ?: 'SUCCESS'

    def color

    if (buildStatus == 'STARTED') {
        color = '#D4DADF'
    } else if (buildStatus == 'SUCCESS') {
        color = '#BDFFC3'
    } else if (buildStatus == 'UNSTABLE') {
        color = '#FFFE89'
    } else {
        color = '#FF9FA1'
    }

    def msg = "${buildStatus}: `${env.JOB_NAME}` #${env.BUILD_NUMBER}:\n${env.BUILD_URL}"

    slackSend(color: color, message: msg)
}

node {
    try {
        notifySlack()

        // Existing build steps.
    } catch (e) {
        currentBuild.result = 'FAILURE'
        throw e
    } finally {
        notifySlack(currentBuild.result)
    }
}

输出将是这样的（尝试不同的格式样式 here）：

可能 env.JOB_NAME 包含编码的斜杠 (%2F)，可以用 replaceAll("%2F", "/") 修复。查看 this Gist 了解如何通知 HipChat。

如果您有 声明式 管道，请查看有关 "Cleaning up and notifications" or Liam Newman's follow-up post "Declarative Pipeline: Notifications and Shared Libraries" 的 Jenkins 文档。

Answer 3

以防万一在声明式语法中，

现在，Jenkins 提供了 post。您可以在管道末尾检查结果。

https://jenkins.io/doc/book/pipeline/syntax/#post-example

像这样使用：

pipeline {
    stages { ... }
    post {
       // only triggered when blue or green sign
       success {
           slackSend ...
       }
       // triggered when red sign
       failure {
           slackSend ...
       }
       // trigger every-works
       always {
           slackSend ...
       }
    }
}

它也会用在每个 stage 中。请参阅文档 link。

Jenkins 管道构建失败后如何发送 Slack 通知？

How to send Slack notification after Jenkins pipeline build failed?

groovy

jenkins

slack

jenkins-pipeline