Antlr4：如何在语法中隐藏和使用令牌

Question

我正在解析定义两种类型语句的脚本语言；控制语句和非控制语句。非控制语句总是以 ';' 结尾，而控制语句可能以 ';' 或 EOL ('\n') 结尾。部分语法如下所示：

script
    :   statement* EOF
    ;

statement
    :   control_statement
    |   no_control_statement
    ;

control_statement
    :   if_then_control_statement
    ;

if_then_control_statement
    :   IF expression THEN end_control_statment
        ( statement ) *
        ( ELSEIF expression THEN end_control_statment ( statement )* )*
        ( ELSE end_control_statment ( statement )* )?
        END IF end_control_statment
    ;

no_control_statement
    :   sleep_statement
    ;

sleep_statement
    :   SLEEP expression END_STATEMENT
    ;

end_control_statment
    :   END_STATEMENT
    |   EOL
    ;

END_STATEMENT
    :   ';'
    ;

ANY_SPACE
    :   ( LINE_SPACE | EOL )    ->  channel(HIDDEN)
    ;

EOL
    :   [\n\r]+
    ;

LINE_SPACE
    :   [ \t]+
    ;

在脚本语言的所有其他方面，我从不关心EOL所以我使用正常的词法分析器规则来隐藏白色space。

这在所有情况下都可以正常工作，但在我需要使用 EOL 来查找控制语句终止的情况下，但是使用上面的语法，所有 EOL 都被隐藏而不是用于控制语句规则。

有没有办法改变我的语法，以便我可以跳过所有 EOL 但需要终止部分控制语句的语法？

Answer 1

找到一种方法来处理这个问题。

我的想法是将 EOL 转移到一个隐藏频道中，而我不想在另一个隐藏频道中看到的其他内容（如空间和评论）。然后我使用一些代码在 EOL 应该出现时回溯令牌并检查以前的令牌通道（因为它们已经被消耗）。如果我在从普通频道运行进入某些内容之前在 EOL 频道上找到了一些内容，那么就可以了。

看起来像这样：

更改了词法分析器规则：

@lexer::members {
    public static int EOL_CHANNEL = 1;
    public static int OTHER_CHANNEL = 2;
}

...

EOL
  : '\r'? '\n'  ->  channel(EOL_CHANNEL)
  ;

LINE_SPACE
  : [ \t]+  ->  channel(OTHER_CHANNEL)
  ;

我还将所有其他隐藏频道（评论）转移到了 OTHER_CHANNEL。然后我改变了规则 end_control_statment:

end_control_statment
  : END_STATEMENT
  | { isEOLPrevious() }?
  ;

并添加

@parser::members {
  public static int EOL_CHANNEL = 1;
  public static int OTHER_CHANNEL = 2;

  boolean isEOLPrevious()
  {
        int idx = getCurrentToken().getTokenIndex();
        int ch;

        do
        {
            ch = getTokenStream().get(--idx).getChannel();
        }
        while (ch == OTHER_CHANNEL);

        // Channel 1 is only carrying EOL, no need to check token itself
        return (ch == EOL_CHANNEL);
     }
}

可以坚持使用普通的隐藏通道，但是在回溯时需要同时跟踪通道和令牌，所以这可能更容易一些...

希望这可以帮助其他人处理此类问题...

Antlr4：如何在语法中隐藏和使用令牌

Antlr4: How can I both hide and use Tokens in a grammar

whitespace

parsing

antlr4