XSL 中的命名空间，从模板 XML 文件复制属性值以更新翻译文件

Question

我的 XSL 文件的任务是从模板源文件中获取属性 'symbol' 值并将其放入翻译文件中，两个文件中的消息编号匹配。此更新似乎有效，但不知何故我遇到了命名空间问题。我不知道为什么，因为模板文件、翻译文件和生成的文件应该都具有完全相同的结构。

首先，我在 Message 元素中获取 xmlns 属性。经过一番谷歌搜索后，我找到了摆脱它们的方法。但是现在我没有在 <Area> 元素中获得我真正想要的 xmlns 属性。

为什么这个重新命名空间对我不起作用？
我怎样才能让它工作？

我的 XSL 文件：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"  xmlns:aaa="urn:aaa-bbb-ccc" exclude-result-prefixes="aaa">
<!-- Transform -s:"translation.xml" -xsl:"merge_files.xsl" -o:"updated_translation.xml" +templateFile="source.xml" -versionmsg:off -->

    <xsl:output method="xml" version="1.0" indent="yes" encoding="utf-8"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="templateFile"/>

    <xsl:variable name="templateDoc" select="$templateFile/aaa:Area" />
    <xsl:variable name="source" select="/" />

    <!--
    <xsl:template match="aaa:Area">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    -->

    <!-- Replacement of the traditional identity rule to avoid getting namespace info in the Message elements. -->
    <xsl:template match="node()[not(self::*)]">
     <xsl:copy>
       <xsl:apply-templates/>
     </xsl:copy>
    </xsl:template>

     <xsl:template match="*">
      <xsl:element name="{local-name()}">
       <xsl:apply-templates select="node()|@*"/>
      </xsl:element>
     </xsl:template>

     <xsl:template match="@*">
      <xsl:attribute name="{local-name()}">
       <xsl:value-of select="."/>
      </xsl:attribute>
     </xsl:template>

    <!-- Getting everything except @symbol from the translation. @symbol is fetched from source/template file. -->
    <xsl:template match="aaa:Message">  
        <xsl:variable name="messageNumber" select="@number"/>
        <Message xmlns:abb="urn:aaa-bbb-ccc" number="{$messageNumber}">
            <xsl:apply-templates select="$templateDoc/aaa:Message[@number=$messageNumber]/@symbol"/>
            <xsl:apply-templates select="node()"/>
        </Message>
    </xsl:template>

</xsl:stylesheet>

我的输入XML文件：

<?xml version="1.0" encoding="utf-8"?>
<Area areaName="YYY" areaNo="2" lang="en" xmlns="urn:aaa-bbb-ccc">
  <Message number="1" symbol="TWINKLE_TWINKLE_LITTLE_STAR">
    <Title>Twinkle Twinkle Little Star</Title>
    <Description>Twinkle, twinkle, little star, How I wonder what you are. Up above the world so high, Like a diamond in the sky.</Description>
  </Message>
  <Message number="2" symbol="SPIDER_SONG1">
    <Title>Itsy-Bitsy Spider</Title>
    <Description>The itsy-bitsy spider climbed up the water spout. Down came the rain and washed the spider out.</Description>
  </Message>
  <Message number="3" symbol="BLACK_SHEEP">
    <Title>Baa, baa, black sheep</Title>
    <Description>Baa, baa, black sheep, have you any wool? Yes sir, yes sir, three bags full!</Description>
  </Message>
</Area>

我输入的翻译文件：

<?xml version="1.0" encoding="utf-8"?>
<Area areaName="YYY" areaNo="2" lang="sv" xmlns="urn:aaa-bbb-ccc">
  <Message number="1" symbol="TWINKLE_STAR">
    <Title>Blinka lilla stjärna</Title>
    <Description>Blinka lilla stjärna där, hur jag undrar vad du är. Fjärran lockar du min syn, lik en diamant i skyn.</Description>
  </Message>
  <Message number="3" symbol="WHITE_SHEEP">
    <Title>Bä, bä, vita lamm</Title>
    <Description>Bä, bä, vita lamm, har du någon ull? Ja, ja, kära barn, jag har säcken full.</Description>
  </Message>
</Area>

预期输出：

<?xml version="1.0" encoding="utf-8"?>
<Area areaName="YYY" areaNo="2" lang="sv" xmlns="urn:aaa-bbb-ccc">
   <Message number="1" symbol="TWINKLE_TWINKLE_LITTLE_STAR">
      <Title>Blinka lilla stjärna</Title>
      <Description>Blinka lilla stjärna där, hur jag undrar vad du är. Fjärran lockar du min syn, lik en diamant i skyn.</Description>
   </Message>
   <Message number="3" symbol="BLACK_SHEEP">
      <Title>Bä, bä, vita lamm</Title>
      <Description>Bä, bä, vita lamm, har du någon ull? Ja, ja, kära barn, jag har säcken full.</Description>
   </Message>
</Area>

这是我现在的输出，其中缺少 'Area' 元素中的 xmlns：

<?xml version="1.0" encoding="utf-8"?>
<Area areaName="YYY" areaNo="2" lang="sv">
   <Message number="1" symbol="TWINKLE_TWINKLE_LITTLE_STAR">
      <Title>Blinka lilla stjärna</Title>
      <Description>Blinka lilla stjärna där, hur jag undrar vad du är. Fjärran lockar du min syn, lik en diamant i skyn.</Description>
   </Message>
   <Message number="3" symbol="BLACK_SHEEP">
      <Title>Bä, bä, vita lamm</Title>
      <Description>Bä, bä, vita lamm, har du någon ull? Ja, ja, kära barn, jag har säcken full.</Description>
   </Message>
</Area>

Answer 1

您的源 XML 中的元素都在命名空间中。我认为您描述的原始问题是因为您在没有命名空间的情况下创建新的 Message 元素，因此它们在输出中显示为 <Message xmlns="">。您尝试解决它实际上会从所有元素中删除名称空间，这并不是真正想要的。

所以，真的只需要使用身份模板来复制元素都保留它们的命名空间....

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

但还要更改 Message 模板以将其输出到正确的命名空间...

<xsl:template match="aaa:Message">  
    <xsl:variable name="messageNumber" select="@number"/>
    <Message xmlns="urn:aaa-bbb-ccc" number="{$messageNumber}">
        <xsl:apply-templates select="$templateDoc/aaa:Message[@number=$messageNumber]/@symbol"/>
        <xsl:apply-templates select="node()"/>
    </Message>
</xsl:template>

试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"  xmlns:aaa="urn:aaa-bbb-ccc" exclude-result-prefixes="aaa">
<!-- Transform -s:"translation.xml" -xsl:"merge_files.xsl" -o:"updated_translation.xml" +templateFile="source.xml" -versionmsg:off -->

    <xsl:output method="xml" version="1.0" indent="yes" encoding="utf-8"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="templateFile"/>

    <xsl:variable name="templateDoc" select="$templateFile/aaa:Area" />
    <xsl:variable name="source" select="/" />

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <!-- Getting everything except @symbol from the translation. @symbol is fetched from source/template file. -->
    <xsl:template match="aaa:Message">  
        <xsl:variable name="messageNumber" select="@number"/>
        <Message xmlns="urn:aaa-bbb-ccc" number="{$messageNumber}">
            <xsl:apply-templates select="$templateDoc/aaa:Message[@number=$messageNumber]/@symbol"/>
            <xsl:apply-templates select="node()"/>
        </Message>
    </xsl:template>

</xsl:stylesheet>

XSL 中的命名空间，从模板 XML 文件复制属性值以更新翻译文件

Namespace in XSL, copying attribute values from a template XML file to update a translated file

xml

xslt

namespaces

xml-namespaces

xslt-1.0