Perl：将一个字节加上 STDIN 传递给另一个命令

Question

我想高效地做到这一点：

my $buf;
my $len = read(STDIN,$buf,1);
if($len) {
    # Not empty                                                                                                          
    open(OUT,"|-", "wc") || die;
    print OUT $buf;
    # This is the line I want to do faster
    print OUT <STDIN>;
    exit;
}

任务是wc只有在有任何输入时才开始。如果没有输入，程序应该直接退出。

wc 只是这里的一个例子。它将被更复杂的命令取代。

输入可以是几 TB 的数据，所以我真的根本不想触及该数据（甚至 sysread 也不行）。我尝试这样做：

    pipe(STDIN,OUT);

但这不起作用。有没有其他方法可以告诉 OUT 在它获得第一个字节后，它应该只从 STDIN 读取？也许一些 open(">=&2") 体操结合 exec?

Answer 1

您感兴趣的具体解决方案是不可能的。

~~正如您肯定已经发现的那样，如果不读取文件句柄就无法确定它是否已达到 EOF。~~ [显然，] select(2) 会让你接近。它会告诉您句柄已到达 EOF 或正在等待数据，但不会告诉您是哪一个。这就是您正在寻找替代解决方案的原因。不幸的是，您正在研究的那个也是不可能的。

Is there some other way that I can tell OUT that after it has gotten the first byte, it should just read from STDIN?

没有。 OUT 不是代码；它不读任何东西。这是一个变量。此外，它是父项中的一个变量。更改父项中的变量不会影响子项。

也许您想问：可以告诉 子程序 从第二个句柄开始读取吗？

没有，一般来说。你不能去编辑另一个程序的变量。该程序必须专门编写为接受两个文件句柄并一个接一个地读取。

再一次，可以获得任意文件句柄的文件名，所以我们只需要一个专门编写的程序来接受两个文件名并从中读取一个接着一个，这很常见。

$ echo abcdef | perl -MFcntl -e'
   if (sysread(STDIN, $buf, 1)) {
      pipe(my $r, my $w);
      my $pid = fork();
      if (!$pid) {
         close($w);

         # Clear close-on-exec flag.
         my $flags = fcntl($r, Fcntl::F_GETFD, 0);
         fcntl($r, Fcntl::F_SETFD, $flags & ~Fcntl::FD_CLOEXEC);

         exec("cat", "/proc/$$/fd/".fileno($r), "/proc/$$/fd/".fileno(STDIN));
         die $!;
      }

      close($r);
      print($w $buf);
      close($w);
      waitpid($pid, 0);
   }
'
abcdef

（需要大量错误检查。）

上面，cat 是一个使用您的程序的示例，但它提供了另一种解决方案：为什么不直接使用 cat？ cat 的开销对于 IO 绑定程序来说应该是很小的。

use String::ShellQuote qw( shell_quote );

my $cmd1 = shell_quote("cat", "/proc/$$/fd/".fileno($r), "/proc/$$/fd/".fileno(STDIN));
my $cmd2 = ...
exec("$cmd1 | $cmd2");

Answer 2

子进程总是获得其父进程的文件句柄的副本，因此只需启动 wc - 使用反引号或调用 system 或 exec - 将导致它从与 Perl 进程 STDIN.

相同的位置读取

至于只有在有东西可读时才开始wc，看起来你需要IO::Select，这将允许你检查文件句柄是否有东西可读，或者阻塞直到确实有东西。

此程序将检查 STDIN 是否有任何数据在等待，运行 wc 如果有则打印其输出。

use strict;
use warnings;

use IO::Select;

my $select = IO::Select->new(\*STDIN);

if ( $select->can_read(0) ) {
  print `wc`;
}

can_read 的参数是以秒为单位的超时。传递零值使其立即 return，如果有数据等待，则报告 true（实际上它 return 是文件句柄本身），或者 false (undef) 如果不是。

如果您不传递参数，那么 can_read 将永远等待直到有内容可读，因此您可以暂停程序并等待 wc 的数据，只需编写

$select->can_read;
print `wc`;

或者你可以结合对象的构造，使其更加简洁

IO::Select->new(\*STDOUT)->can_read;
print `wc`;

另请注意，IO::Select 也适用于文件描述符，并且由于 STDIN 的文件号为零，您可以编写

my $select = IO::Select(0)

但这描述性不强，需要评论才能理解

Answer 3

Perl Cookbook 中提到的 FIONREAD ioctl 可以告诉您有多少字节在文件描述符上待处理而不消耗它们.用波斯语来说：

use strict;
use warnings;

use IO::Select qw( );    
BEGIN { require 'sys/ioctl.ph'; }

sub fionread {
    my $sz = pack('L', 0);
    return unless ioctl($_[0], FIONREAD, $sz);
    return unpack('L', $sz);
}

# Wait until it's known whether the handle has data to read or has reached EOF.
IO::Select->new(\*STDIN)->can_read();

if (fionread(\*STDIN)) {
    system('wc');
    # Check for errors
}

这应该可以非常广泛地移植到 UNIX 和类 UNIX 平台。

Perl：将一个字节加上 STDIN 传递给另一个命令

Perl: Pass one byte plus STDIN to another command

io

perl