CMake 无法 link CLion 中的 libxml2

Question

tl;dr 将 set(CMAKE_CXX_STANDARD_LIBRARIES "-lxml2" ) 添加到 CMakeLists.txt（更多信息见下方）。

我想运行 CLion 中的一个非常简单的应用程序。此应用程序使用 libxml2.

我在 Ubuntu 18.04 LTS 上使用 CLion 2018.1.2，libxml2-dev 已正确安装。

我的项目确实编译了：

g++ -I /usr/include/libxml2 xmlTest.cpp -o xmlTest.exe -lxml2

它不会在 CLion 中编译，使用这个 CMakeLists.txt:

cmake_minimum_required(VERSION 3.10)
project(xmlTest)

set(CMAKE_CXX_STANDARD 11)
set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -I/usr/include/libxml2 -lxml2 -lz -lm")

include_directories( /usr/local/include/libxml2 )

add_executable (xmlTest.exe xmlTest.cpp)

编译器抛出我：

/home/xxxx/.local/share/JetBrains/Toolbox/apps/CLion/ch-0/181.4668.70/bin/cmake/bin/cmake --build /home/xxxx/src/cmake-build-debug --target xmlTest.exe -- -I /usr/include/libxml2 -lxml2
Scanning dependencies of target xmlTest.exe
[ 50%] Building CXX object CMakeFiles/xmlTest.exe.dir/xmlTest.cpp.o
[100%] Linking CXX executable xmlTest.exe
CMakeFiles/xmlTest.exe.dir/xmlTest.cpp.o: In function `main':
/home/xxxx/src/xmlTest.cpp:10: undefined reference to `xmlReadFile'
/home/xxxx/src/xmlTest.cpp:17: undefined reference to `xmlDocGetRootElement'
/home/xxxx/src/xmlTest.cpp:21: undefined reference to `xmlFreeDoc'
/home/xxxx/src/xmlTest.cpp:25: undefined reference to `xmlStrcmp'
/home/xxxx/src/xmlTest.cpp:27: undefined reference to `xmlFreeDoc'

我的申请（xmlTest.cpp）：

#include <stdlib.h>
#include <stdio.h>
#include <libxml/parser.h>
#include <libxml/tree.h>

int main(int argc, char const *argv[]) {
  xmlDocPtr doc;
  xmlNodePtr cur;

  doc = xmlReadFile(argv[1], NULL, 0);

  if (doc == NULL ) {
    fprintf(stderr,"Document not parsed successfully. \n");
    return 1;
  }

  cur = xmlDocGetRootElement(doc);

  if (cur == NULL) {
    fprintf(stderr,"empty document\n");
    xmlFreeDoc(doc);
    return 1;
  }

  if (xmlStrcmp(cur->name, (const xmlChar *) "users")) {
    fprintf(stderr,"document of the wrong type, root node != story");
    xmlFreeDoc(doc);
    return 1;
  }

  return 0;
}

在摆弄 libxml2 和 CMake 数小时后仍未成功，我很乐意知道如何告诉 CMake libxml2 实际存在...

更新#1：

感谢@vre 的建议，我更新了我的 CMakeLists.txt 文件：

cmake_minimum_required(VERSION 3.10)
project(xmlTest)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -I/usr/include/libxml2 -lxml2 -lz -lm")
set(CMAKE_CXX "/usr/local/include/libxml2")
find_library(libxml2 libxml2)
link_directories(/usr/local/include/libxml2)
add_compile_options("-I/usr/include/libxml2 -lxml2 -lz -lm")
find_package(LibXml2 REQUIRED)
add_executable (xmlTest.exe xmlTest.cpp)
target_compile_definitions(xmlTest.exe PUBLIC ${LibXml2_DEFINITIONS})
target_include_directories(xmlTest.exe PUBLIC ${LibXml2_INCLUDE_DIRS})
target_link_libraries(xmlTest.exe ${LibXml2_LIBRARIES})

虽然这并没有改变或解决错误。

更新 #2（解决方案）：

这是在 CLion 中使用 libxml2 构建项目的方法：

cmake_minimum_required(VERSION 3.10)
project(xmlTest)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -I/usr/include/libxml2")
set(CMAKE_CXX_STANDARD_LIBRARIES "-lxml2" )

add_executable (xmlTest.exe xmlTest.cpp)

我的问题是我的 CMAKE_CXX_FLAGS 中的参数顺序错误。 This article points this out. Using set(CMAKE_CXX_STANDARD_LIBRARIES "-lxml2" ) was the key ()

我希望这对未来的时间旅行者有所帮助：

Answer 1

您提出的解决方案有效，但 CMake 的目的是提供表达平台、编译器和构建工具的独立方式来描述项目。所有的魔法都发生在 FindLibXml2.cmake 模块中。并且交付了大量模块，可以与您的 CMake 安装一起使用。在 Ubuntu 18.04.

上查看 /usr/share/cmake-3.10/Modules 下的模块目录

如果您按以下方式重新制定 CMakeLists.txt：

cmake_minimum_required(VERSION 3.10)

project(xmlTest)

set(CMAKE_CXX_STANDARD 11)
if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
elseif(MSVC)
  # add options for Visual C/C++ Compiler here
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
endif()    

find_package(LibXml2 REQUIRED)

add_executable(xmlTest.exe xmlTest.cpp)

target_compile_definitions(xmlTest.exe PUBLIC ${LIBXML2_DEFINITIONS})
target_include_directories(xmlTest.exe PUBLIC ${LIBXML2_INCLUDE_DIRS})
target_link_libraries(xmlTest.exe ${LIBXML2_LIBRARIES})

您能够在广泛的平台以及编译器和 IDE 的组合上工作。这是在 Ubuntu 18.04 上用 GCC 7.3 和 Windows 10 上用 MSVC 15 测试的。您需要更多步骤来构建 Windows（即安装和设置 libxml2 及其所有依赖项）。而这个应该也可以直接与 CLion 一起使用。

CMake 无法 link CLion 中的 libxml2

CMake unable to link libxml2 in CLion

c++

cmake

libxml2

clion