CLIPS：强制规则重新评估全局变量的值？

Question

是否有可能导致 CLIPS 重新评估 defrule 中的全局变量的值？我有这个：

(defrule encourage "Do we have a GPA higher than 3.7?"
    (test (> (gpa) 3.7))
    =>
    (printout t "Keep up the excellent work!" crlf))

gpa 是根据两个全局变量（成绩点和学分）计算和 returns 一个数字的函数。我在某处读到对全局变量的更改不会调用模式匹配。我该如何强制执行此操作？只要 GPA 高于 3.7，我每次都想打印该字符串 (运行)。

Answer 1

不要尝试以这种方式使用全局变量或函数调用。首先，全局变量专门设计为不触发模式匹配。其次，CLIPS 需要一点魔法才能知道何时需要重新评估函数调用，因为有任何数量的更改都可能导致函数 return 不同的值，而不仅仅是更改全局变量。如果你想要一条特定的信息来触发模式匹配，那么就把它贴在一个事实或实例中。如果您对函数调用进行参数化并将值绑定为规则条件中的参数，这将使您的代码更容易理解。

CLIPS> (clear)
CLIPS> 
(deffunction gpa (?grade-points ?number-of-credits)
   (/ ?grade-points ?number-of-credits))
CLIPS>    
(defrule encourage "Do we have a GPA higher than 3.7?"
    (grade-points ?gp)
    (number-of-credits ?noc)
    (test (> (gpa ?gp ?noc) 3.7))
    =>
    (printout t "Keep up the excellent work!" crlf))
CLIPS> (assert (grade-points 35) (number-of-credits 10))
<Fact-2>
CLIPS> (agenda)
CLIPS> (facts)
f-0     (initial-fact)
f-1     (grade-points 35)
f-2     (number-of-credits 10)
For a total of 3 facts.
CLIPS> (retract 1)
CLIPS> (assert (grade-points 38))
<Fact-3>
CLIPS> (agenda)
0      encourage: f-3,f-2
For a total of 1 activation.
CLIPS>

或者，您可以使用事实查询函数迭代一组事实，以基于事实而不是全局动态计算 gpa。每次修改其中一个事实（添加或删除）时，您还可以断言一个事实，表明需要重新检查 gpa 以触发鼓励规则。

CLIPS> (clear)
CLIPS> 
(deftemplate grade
   (slot class)
   (slot grade-points)
   (slot credits))
CLIPS> 
(deffunction gpa ()
   (bind ?grade-points 0)
   (bind ?credits 0)
   (do-for-all-facts ((?g grade)) TRUE
      (bind ?grade-points (+ ?grade-points ?g:grade-points))
      (bind ?credits (+ ?credits ?g:credits)))
   (if (= ?credits 0)
      then 0
      else (/ ?grade-points ?credits)))
CLIPS> 
(defrule encourage
   ?f <- (check-gpa)
   =>
   (retract ?f)
   (if (> (gpa) 3.7)
      then
      (printout t "Keep up the excellent work!" crlf)))
CLIPS> (gpa)
0
CLIPS> (assert (check-gpa))
<Fact-1>
CLIPS> (run)
CLIPS>  (assert (grade (class Algebra) (grade-points 12) (credits 3)))
<Fact-2>
CLIPS> (gpa)
4.0
CLIPS> (assert (check-gpa))
<Fact-3>
CLIPS> (run)
Keep up the excellent work!
CLIPS> (assert (grade (class History) (grade-points 6) (credits 2)))
<Fact-4>
CLIPS> (gpa)
3.6
CLIPS> (assert (check-gpa))
<Fact-5>
CLIPS> (run)
CLIPS> (assert (grade (class Science) (grade-points 12) (credits 3)))
<Fact-6>
CLIPS> (gpa)
3.75
CLIPS> (assert (check-gpa))
<Fact-7>
CLIPS> (run)
Keep up the excellent work!
CLIPS>

CLIPS：强制规则重新评估全局变量的值？

CLIPS: forcing a rule to re-evaluate the value of a global variable?

clips