链接服务器 COMMIT TRANSACTION 在 TRY CATCH 上失败

Question

我正在使用链接服务器，这段代码工作正常

BEGIN TRY
    INSERT INTO [Dev].[dbo].tb_test (no)  SELECT no from [MYLINKEDSERVER].[mydb].[dbo].tb_test 
    DELETE FROM [MYLINKEDSERVER].[mydb].[dbo].tb_test
END TRY
BEGIN CATCH
    SELECT 'fail'
END CATCH

但是当我将它与 COMMIT TRANSACTION 一起使用时，就像这样

BEGIN TRY
    BEGIN TRANSACTION 
    INSERT INTO [Dev].[dbo].tb_test (no)  SELECT no from [MYLINKEDSERVER].[mydb].[dbo].tb_test 
    DELETE FROM [MYLINKEDSERVER].[mydb].[dbo].tb_test
    COMMIT
END TRY
BEGIN CATCH
    IF @@TRANCOUNT > 0
        ROLLBACK
END CATCH

显示错误

OLE DB provider "SQLNCLI11" for linked server "MYLINKEDSERVER" returned message "The partner transaction manager has disabled its support for remote/network transactions.".

怎么了？

Answer 1

尝试在要进行插入操作的服务器上执行以下命令。

EXEC sp_serveroption @server = 'ReadServerName',@optname = 'remote proc transaction promotion', @optvalue = 'false' ;

也尝试执行下面的代码。我添加了 BEGIN DISTRIBUTED TRANSACTION 而不是 BEGIN TRANSACTION。

BEGIN TRY
    BEGIN DISTRIBUTED TRANSACTION
    INSERT INTO [Dev].[dbo].tb_test (no)  SELECT no from [MYLINKEDSERVER].[mydb].[dbo].tb_test 
    DELETE FROM [MYLINKEDSERVER].[mydb].[dbo].tb_test
    COMMIT
END TRY
BEGIN CATCH
    IF @@TRANCOUNT > 0
        ROLLBACK
END CATCH

详情请见 MS site。

Answer 2

试试这个应该有用

DECLARE @ServerName SYSNAME
, @Message nvarchar(1000)
, @CMD1 nvarchar(max)
--
DECLARE @Server_List Table
( SrvID SMALLINT
, SrvName SYSNAME )
--
Set NoCount ON
--
-- Load up linked server list
--
BEGIN
INSERT INTO @Server_List (SrvID, SrvName)
SELECT SrvID
, SrvName 
FROM [master].[SYS].sysservers
ORDER BY SrvID ASC
END
--
SELECT TOP 1 @ServerName = SrvName
FROM @Server_List
ORDER BY SrvID ASC
--
-- Loop through the Linked Server List
--
WHILE EXISTS ( SELECT * FROM @Server_List )
BEGIN
SELECT @Message = 'Server Name is '+ @ServerName
--
RAISERROR (@Message, 10,1) WITH NOWAIT
--
SET @CMD1 = 'EXEC master.dbo.sp_serveroption @server=N'''
+ @ServerName
+ ''', @optname=N''rpc'', @optvalue=N''true'''
Exec sp_executesql @cmd1
--
SET @CMD1 = 'EXEC master.dbo.sp_serveroption @server=N'''
+ @ServerName
+ ''', @optname=N''rpc out'', @optvalue=N''true'''
Exec sp_executesql @cmd1
--
set @cmd1 = 'EXEC master.dbo.sp_serveroption @server = '''
+ @ServerName
+ ''', @optname=N''remote proc transaction promotion'', @optvalue=N''false'''
Exec sp_executesql @stmt=@cmd1,@params=N''
--
DELETE FROM @Server_List WHERE SrvName = @ServerName
--
SELECT TOP 1 @ServerName = SrvName
FROM @Server_List
ORDER BY SrvID ASC
--
END

Answer 3

解决办法是用return值在远程服务器上写一个存储过程，在本地执行：

BEGIN TRY
BEGIN TRANSACTION 
    INSERT INTO [Dev].[dbo].tb_test (no)  
        SELECT no 
        FROM [MYLINKEDSERVER].[mydb].[dbo].tb_test 

    DECLARE @returnvalue INT

    EXEC @returnvalue = [MYLINKEDSERVER].[mydb].[dbo].sp_update @no

    IF @returnvalue = 1
    BEGIN
        COMMIT
    END
    ELSE 
    BEGIN
        ROLLBACK
    END
END TRY
BEGIN CATCH
    IF @@TRANCOUNT > 0
        ROLLBACK
END CATCH

存储过程：

CREATE PROCEDURE [dbo].[sp_update] 
     @no NVARCHAR(20)
AS
BEGIN
    SET NOCOUNT ON

    BEGIN TRY
        BEGIN TRANSACTION
            DELETE FROM mytb 
            WHERE no = @no

            COMMIT
            RETURN 1
    END TRY
    BEGIN CATCH
        IF @@TRANCOUNT > 0
            ROLLBACK
        RETURN 0
    END CATCH
END

希望对某人有所帮助

链接服务器 COMMIT TRANSACTION 在 TRY CATCH 上失败

Linked Server COMMIT TRANSACTION fail on TRY CATCH

sql-server

linked-server