为什么我可以在没有正确数量输入的情况下通过 f2py 调用 Fortran 子例程？

Question

我正在努力学习 f2py 并且我有以下 Fortran 代码

      subroutine fibonacci(a, n)
      implicit none
      integer :: i, n
      double precision :: a(n)
      do i = 1, n
          if (i .eq. 1) then
              a(i) = 0d0
          elseif (i .eq. 2) then
              a(i) = 1d0
          else 
              a(i) = a(i - 1) + a(i - 2)
          endif
      enddo
      end subroutine fibonacci

用 f2py -c fibonacci.f -m fibonacci 编译，然后在 Python

中调用

import numpy
import fibonacci

a = numpy.zeros(13)
fibonacci.fibonacci(a)
print a

在 Python 中调用的子例程 fibonacci 没有获得足够数量的参数，但代码神秘地起作用了。顺便说一句，用 fibonacci.fibonacci(a, len(a)) 调用子程序 fibonacci 也有效！

有人可以解释一下吗？谢谢！

Answer 1

f2py知道a和n是函数参数，从声明

double precision :: a(n)

可以推断出n是a的长度。 NumPy 数组有长度，因此 Python 包装器中不需要参数 n，f2py 使其可选。

请注意，f2py 生成的代码会检查您没有为 n 提供太大的值：

In [19]: a = np.zeros(10)

In [20]: fibonacci.fibonacci(a, 99)
---------------------------------------------------------------------------
error                                     Traceback (most recent call last)
<ipython-input-20-e9497469fd10> in <module>()
----> 1 fibonacci.fibonacci(a, 99)

error: (len(a)>=n) failed for 1st keyword n: fibonacci:n=99

您可以给一个较小的值：

In [21]: a = np.zeros(10)

In [22]: fibonacci.fibonacci(a, 6)

In [23]: a
Out[23]: array([0., 1., 1., 2., 3., 5., 0., 0., 0., 0.])

您可能会发现生成并查看 f2py 为此函数生成的接口文件很有用。命令

f2py -h fibonacci.pyf fibonacci.f

显示

Reading fortran codes...
    Reading file 'fibonacci.f' (format:fix,strict)
Post-processing...
    Block: fibonacci
Post-processing (stage 2)...
Saving signatures to file "./fibonacci.pyf"

并生成文件 fibonacci.pyf，其中包含

!    -*- f90 -*-
! Note: the context of this file is case sensitive.

subroutine fibonacci(a,n) ! in fibonacci.f
    double precision dimension(n) :: a
    integer, optional,check(len(a)>=n),depend(a) :: n=len(a)
end subroutine fibonacci

! This file was auto-generated with f2py (version:2).
! See http://cens.ioc.ee/projects/f2py2e/

从生成的声明可以看出

    integer, optional,check(len(a)>=n),depend(a) :: n=len(a)

f2py推断出n应该是一个可选参数，其值不能超过a的长度，默认值为len(a)。

为什么我可以在没有正确数量输入的情况下通过 f2py 调用 Fortran 子例程？

Why can I call Fortran subroutine through f2py without having right number of inputs?

python

fortran

f2py