我可以在 Sagemath 中创建 "abstract" 个张量吗？

Question

例如，我想在不指定系数的情况下采用单形式的外导数。例如，如果我有一个表格

a = fdz + gdx + hdy

我如何根据 f_x、f_y 等计算 da，而不告诉 Sage 确切的 f、g 和 h 是什么？

我尝试查看 Sage 网站的微分形式和张量部分，但没有找到任何内容。

Answer 1

显然这在某种程度上是可能的，但可能有限（当前实用性）。

sage: U = Manifold(3, 'U')
sage: X.<x,y,z> = U.chart()
sage: f = U.diff_form(2, 'f')
sage: f
2-form f on the 3-dimensional differentiable manifold U
sage: f.exterior_derivative()
3-form df on the 3-dimensional differentiable manifold U

所以至少还有抽象的。但是

sage: f.components()
...
ValueError: no basis could be found for computing the components in the Coordinate frame (U, (d/dx,d/dy,d/dz))

但是，我认为可以通过定义三个变量的抽象函数来解决这个问题。不能保证这是否 100% 准确，因为 "chart" 变量与其他符号变量的关系对我来说并不清楚 - 我没有使用 SageManifolds 太多。

sage: pbi = function('pbi', nargs=3)(x,y,z); pbi
pbi(x, y, z)
sage: type(pbi)
<type 'sage.symbolic.expression.Expression'>
sage: f[0,1]=pbi
sage: f
2-form f on the 3-dimensional differentiable manifold U
sage: f.components()
Fully antisymmetric 2-indices components w.r.t. Coordinate frame (U, (d/dx,d/dy,d/dz))
sage: f.display()
f = pbi(x, y, z) dx/\dy
sage: f.exterior_derivative()
3-form df on the 3-dimensional differentiable manifold U
sage: f.exterior_derivative().components()
Fully antisymmetric 3-indices components w.r.t. Coordinate frame (U, (d/dx,d/dy,d/dz))
sage: f.exterior_derivative().display()
df = d(pbi)/dz dx/\dy/\dz
sage: f[1,2]=pbi^2
sage: f.exterior_derivative().display()
df = (2*pbi(x, y, z)*d(pbi)/dx + d(pbi)/dz) dx/\dy/\dz

如果这些计算符合您的预期，那么我想您可以使用它们。快速浏览一下表面，至少 +/- 似乎是正确的。

sage: g = U.diff_form(1, 'g')
sage: g[:] = (pbi,pbi^2,pbi^3)
sage: g.display()
g = pbi(x, y, z) dx + pbi(x, y, z)^2 dy + pbi(x, y, z)^3 dz
sage: g.exterior_derivative().display()
dg = (2*pbi(x, y, z)*d(pbi)/dx - d(pbi)/dy) dx/\dy + (3*pbi(x, y, z)^2*d(pbi)/dx - d(pbi)/dz) dx/\dz + (3*pbi(x, y, z)^2*d(pbi)/dy - 2*pbi(x, y, z)*d(pbi)/dz) dy/\dz

请参阅 here（但只有流形版本，另一个已弃用），除了您已经提到的文档之外，还有更多示例。

我可以在 Sagemath 中创建 "abstract" 个张量吗？

Can I create "abstract" tensors in Sagemath?

symbolic-math

sage

tensor