新年日期之间的周数问题

Question

问题

下面的[mcve] 将输出两个日期之间的周数数组。它适用于两个日期都在同一年的情况，但是，有些年份有 52 周并且从去年的最后几天开始。而其他人有53周。

52 周的一个例子是 2020 calendar:

第一周从 12 月 30 日开始。

53周的例子是2016 calendar:

1 月 4 日才开始。

代码

以下代码被注释并输出一个包含周数的数组。

Sub w_test()
    Dim Arr() As Variant, ArrDateW() As Variant
    'Initial Date
    DateI = DateSerial(2015, 5, 5)
    'Final Date
    DateF = DateSerial(2017, 9, 20)
    'Difference in weeks between DateI and DateF
    weekDif = DateDiff("ww", DateI, DateF) + k - 1

    i = Weekday(DateI)
    d = DateI

    'If not Sunday, go back to last week, to start the loop
    If i <> 1 Then
        d = DateAdd("d", -(i - 1), d)
    End If

    ReDim ArrDateW(weekDif)
    ReDim Arr(2)
    'Loop on all weeks between two dates to populate array of arrays
    For i = 0 To weekDif
        'Date
        Arr(0) = d
        'Trying to solve problem with New Year
        If Application.WorksheetFunction.WeekNum(d) = 53 Then
            flag = True
        End If
        If flag = False Then
            Arr(1) = Application.WorksheetFunction.WeekNum(d)
        Else
            Arr(1) = Application.WorksheetFunction.WeekNum(DateSerial(Year(d) + 1, 1, 1))
            flag = False
        End If

        'Year
        Arr(2) = Year(d)
        'Populate array of arrays
        ArrDateW(i) = Arr
        'Next Week Number
        d = DateAdd("ww", 1, d)
    Next i

    'To stop with Ctrl+F8
    Debug.Print d
End Sub

问题

2015 年有 53 周，但程序输出如下：

而在2016 and 2017之间，输出一团糟：

如何修复程序以正确输出这些周数？

Answer 1

我的做法有所不同，依靠 built-in VBA 函数来正确计算周数。如果您认为有必要，请阅读 ISO 周数 and see how I'm using the DataPart function -- though you can substitute your own version of Ron de Bruin's ISO week number function。

几个简短的旁注：

Always use Option Explicit
尽量使用更具描述性的变量名。你知道你现在在说什么。几个月后，您将很难记住 d 和 Arr 的意思（即使现在看起来很明显）。这只是一个好习惯，使代码 self-documenting.
我下面的示例将逻辑分解为一个单独的函数，其中包含一个可选参数（只是为了好玩），允许调用者将一周的开始更改为不同的一天。

代码模块：

Option Explicit

Sub w_test()
    Dim initialDate As Date
    Dim finaldate As Date
    initialDate = #5/5/2015#
    finaldate = #9/29/2017#

    Dim weeks As Variant
    weeks = WeekNumbers(initialDate, finaldate)

    Debug.Print "There are " & UBound(weeks, 1) & " weeks between " & _
                Format(initialDate, "dd-mmm-yyyy") & " and " & _
                Format(finaldate, "dd-mmm-yyyy")
End Sub

Private Function WeekNumbers(ByVal initialDate As Date, _
                             ByVal finaldate As Date, _
                             Optional ByVal weekStart As VbDayOfWeek = vbSunday) As Variant
    Dim numberOfWeeks As Long
    numberOfWeeks = DateDiff("ww", initialDate, finaldate, weekStart, vbFirstFullWeek)

    Dim startOfWeek As Date
    If Weekday(initialDate) <> vbSunday Then
        Dim adjustBy As Long
        If Weekday(initialDate) > weekStart Then
            adjustBy = Weekday(initialDate) - weekStart
        Else
            adjustBy = (Weekday(initialDate) + 7) - weekStart
        End If
        startOfWeek = DateAdd("d", -adjustBy, initialDate)
    End If

    Dim allTheWeeks As Variant
    ReDim allTheWeeks(1 To numberOfWeeks)

    Dim weekInfo As Variant
    ReDim weekInfo(1 To 3)

    Dim i As Long
    For i = 1 To numberOfWeeks
        weekInfo(1) = startOfWeek
        weekInfo(2) = DatePart("ww", startOfWeek, weekStart, vbFirstFourDays)
        weekInfo(3) = Year(startOfWeek)
        allTheWeeks(i) = weekInfo
        startOfWeek = DateAdd("ww", 1, startOfWeek)
    Next i

    WeekNumbers = allTheWeeks
End Function

新年日期之间的周数问题

Problem with Week Numbers between dates on New Year

excel

vba

calendar

week-number

问题

代码

问题

如何修复程序以正确输出这些周数？