Return 关系作为树中的子节点 (Neo4j Cypher)

Question

有没有办法将关系检索为树的子元素？

这是我掌握的基础数据：

CREATE (:Customer {id:1, name:'Customer 1'})<-[:CREATED_BY]-(c:Category {id:1, name:'Category 1'})
WITH c as category, range(2, 7) as subCatIds
FOREACH (s IN subCatIds | CREATE (category)<-[:SUBCATEGORY_OF]-(:Category {id:s, name:'SubCategory '+s}))
WITH category, range(1, 5) as attTypeIds
FOREACH (a IN attTypeIds | CREATE (category)-[:HAS_ATTRIBUTE {name:'Attribute '+a, required: (a%2=0)}]->(:AttributeType {id:a, name:'AttributeType '+a}))
WITH category
MATCH p = (:AttributeType)<-[:HAS_ATTRIBUTE]-(category)<-[:SUBCATEGORY_OF]-(:Category)
RETURN p

所以这个查询returns正确的树结构：

MATCH  (:Customer {id:1})<-[:CREATED_BY]-(c:Category {id:1}),
       p = (c)<-[:SUBCATEGORY_OF*0..1]-(:Category)
WITH COLLECT(p) as category
CALL apoc.convert.toTree(category) yield value
RETURN value

如何将关系 [:HAS_ATTRIBUTE] 作为子节点添加到此查询？

我已经试过了：

MATCH  (:Customer {id:1})<-[:CREATED_BY]-(c:Category {id:1}),
       SubCatsP = (c)<-[:SUBCATEGORY_OF*0..1]-(:Category),
       AttP = (c)-[:HAS_ATTRIBUTE]->(att:AttributeType)
WITH COLLECT(SubCatsP) as category, RELATIONSHIPS(AttP) as attributes
CALL apoc.convert.toTree(category) yield value
RETURN value, attributes

但是这 returns 5 条记录（每个关系 1 条记录 [:HAS_ATTRIBUTE]）重复了类别-子类别树。

我希望结果是：

{
 id: 1,
 name: 'Category 1',
 SUBCATEGORY_OF:[
   {id:2, name: 'Subcategory 2'}, ...
  ]
 HAS_ATTRIBUTE:[
   {name: 'Attribute 1', required: false, att: {name:'AttributeType 5',id:5}}, ...
<OR>
{name: 'Attribute 1', required: false, att.name:'AttributeType 5',att.id:5}, ...
  ]
}

这是否可能，或者您是否考虑使用更好的方法来执行 2 个单独的查询？

Answer 1

您可以尝试将路径组合成一个列表：

MATCH  (:Customer {id:1})<-[:CREATED_BY]-(c:Category {id:1}),
   SubCatsP = (c)<-[:SUBCATEGORY_OF*0..1]-(:Category),
   AttP = (c)-[:HAS_ATTRIBUTE]->(att:AttributeType)
WITH COLLECT(SubCatsP) + COLLECT(AttP) as category
CALL apoc.convert.toTree(category) yield value
RETURN value

Return 关系作为树中的子节点 (Neo4j Cypher)

Return relations as child nodes in tree (Neo4j Cypher)

neo4j

cypher

neo4j-apoc