java.lang.ClassNotFoundException: org.postgresql.Driver 来自jooq代码生成任务

Question

我正在实施 java-spring-boot 项目（jdk11，spring boot 2.3.0.RELEASE），后端使用 jooq-hikari-hibernate-postgres .

我已经使用 flyway 创建了表格。

我在build.gradle中创建了一个任务名称"generateJooqRepo"来生成java存储库的代码。任务是运行但是失败并显示错误消息：

Execution failed for task ':generateJooqRepo'.
  > java.lang.ClassNotFoundException: org.postgresql.Driver

对我做错了什么有任何见解吗？

build.gradle:

import org.jooq.codegen.*

plugins {
    id 'org.springframework.boot' version '2.3.0.RELEASE'
    id 'org.flywaydb.flyway' version '6.4.4'
    id "nu.studer.jooq" version "4.2"
}

apply plugin: 'io.spring.dependency-management'
apply plugin: 'application'
apply plugin: 'maven'
apply plugin: 'jacoco'
apply plugin: 'idea'
apply plugin: 'nu.studer.jooq'

configurations {
    deployerJars
}


sourceCompatibility = '11.0.1'
targetCompatibility = '11.0.1'

repositories {
    // Use jcenter for resolving your dependencies.
    // You can declare any Maven/Ivy/file repository here.
    jcenter()
    mavenCentral()

}



dependencies {

    //Spring Dependencies
    implementation 'org.springframework.boot:spring-boot-starter-actuator:2.3.0.RELEASE'
    implementation 'org.springframework.boot:spring-boot-starter-web:2.3.0.RELEASE'

    //postges
    jooqRuntime  'org.postgresql:postgresql:42.2.14'
    implementation 'org.postgresql:postgresql:42.2.14'

    //The gradle-jooq-plugin needs dependencies in a separate configuration.
    // It uses the jooqRuntime configuration to detect the needed dependencies, it doesn't use the compile or implementation configuration.
    jooqRuntime group: 'org.jooq', name: 'jooq-meta-extensions', version: '3.13.2'

    //flyway
    compile 'org.flywaydb:flyway-core:6.4.4'

    //jooq dependency
    implementation 'org.springframework.boot:spring-boot-starter-jooq:2.3.0.RELEASE'
    compile 'org.jooq:jooq:3.13.2'
    compile 'org.jooq:jooq-meta:3.13.2'
    compile 'org.jooq:jooq-codegen:3.13.2'


    // This dependency is found on compile classpath of this component.
    implementation 'org.apache.commons:commons-lang3:3.9'
}

group = 'com.ringo.tapos.service'
version = '1.0.0-SNAPSHOT'
mainClassName = "com.ringo.tapos.service.Application"


// Use your favourite XML builder to construct the code generation configuration file
// ----------------------------------------------------------------------------------
task generateJooqRepo {
    doLast {
        def writer = new StringWriter()
        def xml = new groovy.xml.MarkupBuilder(writer)
                .configuration('xmlns': 'http://www.jooq.org/xsd/jooq-codegen-3.13.0.xsd') {
                    jdbc() {
                        driver('org.postgresql.Driver')
                        url('jdbc:postgresql://localhost:5432/postgres')
                        user('postgres')
                        password('postgres')
                        schema('tapos')
                    }
                    generator() {
                        database() {
                        }
                        generate([:]) {
                            pojos true
                            daos true
                            relations true
                            deprecated false
                            records true
                            //immutablePojos false
                        }
                        target() {
                            packageName('com.ringo.tapos.service.repositories')
                            directory('src/main/java')
                        }
                    }
                }
        GenerationTool.generate(writer.toString())
    }
}

Answer 1

您还应该将 postgres 驱动程序依赖项添加到 jooqRuntime 配置中 jooqRuntime 'org.postgresql:postgresql:42.2.14'

更新：如果您想在 gradle 脚本中使用它，而不是 nu.studer.jooq 插件

提供的任务，您应该将 postgres 驱动程序添加到您的构建脚本类路径中

buildscript {
    dependencies {
        classpath  'org.postgresql:postgresql:42.2.14'
    }
}

java.lang.ClassNotFoundException: org.postgresql.Driver 来自jooq代码生成任务

java.lang.ClassNotFoundException: org.postgresql.Driver from jooq code generating task

java

gradle

jooq

jooq-codegen-maven