面对 Terraform KeyVault 证书创建问题

Question

大家好，我遇到了一个问题，我有一个脚本，我在其中创建资源组和密钥保管库，当我单独创建 RG 和密钥保管库时，我将凭证从中央 KV 复制到新的，然后添加凭证复制部分在脚本中创建了所有内容，但是当我将 1 RG 和 1 KV 的代码与凭据副本组合在一起时，它说 RG 中的错误密钥保管库不存在。我想问我需要遵循 terraform 中的任何顺序吗？ Resource.tf

resource "azurerm_resource_group" "main" {
  name     = "${var.prefix}-resourceGB"
  location = var.location
}

# --- Get reference to logged on Azure subscription ---
data "azurerm_client_config" "current" {}


resource "azurerm_key_vault" "New" {
  name                        = "KV1"
  location                    = azurerm_resource_group.main.location
  resource_group_name         = azurerm_resource_group.main.name
  enabled_for_disk_encryption = true
  tenant_id                   = data.azurerm_client_config.current.tenant_id
  soft_delete_enabled         = true
  purge_protection_enabled    = false


  sku_name = "standard"


  access_policy {
    tenant_id = data.azurerm_client_config.current.tenant_id
    object_id = data.azurerm_client_config.current.object_id

    certificate_permissions = [
      "create",
      "delete",
      "deleteissuers",
      "get",
      "getissuers",
      "import",
      "purge",
      "list",
      "listissuers",
      "managecontacts",
      "manageissuers",
      "setissuers",
      "update",
    ]

    key_permissions = [
      "backup",
      "create",
      "decrypt",
      "delete",
      "encrypt",
      "get",
      "import",
      "list",
      "purge",
      "recover",
      "restore",
      "sign",
      "unwrapKey",
      "update",
      "verify",
      "wrapKey",
    ]

    secret_permissions = [
      "backup",
      "delete",
      "get",
      "list",
      "purge",
      "recover",
      "restore",
      "set",
    ]


  }
}
data "azurerm_key_vault" "existing" {
  name                = "Old-KV"
  resource_group_name = "Old-RG"

}

data "azurerm_key_vault" "New" {
  name                = "KV1"
  resource_group_name = "${var.prefix}-resourceGB"
}

module "Cert1" {
  source = "../module/copy_cert"
  source_key_vault_id = data.azurerm_key_vault.existing.id
  source_key_vault_cert_name = "Cert1"
  destination_key_vault_id = data.azurerm_key_vault.New.id
  destination_key_vault_cert_name = "Cert1"

}
module "Cert2" {
  source = "../module/copy_cert"
  source_key_vault_id = data.azurerm_key_vault.existing.id
  source_key_vault_cert_name = "Cert2"
  destination_key_vault_id = data.azurerm_key_vault.New.id
  destination_key_vault_cert_name = "Cert2"

}

复制证书main.tf

data "azurerm_key_vault_secret" "source_KV_cert" {
  name         = var.source_key_vault_cert_name
  key_vault_id = var.source_key_vault_id
}


data "azurerm_key_vault_certificate" "source_cert" {
  name         = var.source_key_vault_cert_name
  key_vault_id = var.source_key_vault_id
}


resource "azurerm_key_vault_certificate" "dest_cert" {
  name         = var.destination_key_vault_cert_name
  key_vault_id = var.destination_key_vault_id


certificate {
    contents = data.azurerm_key_vault_secret.source_KV_cert.value
  }


  certificate_policy {
    issuer_parameters {
      name = "self"
    }


    key_properties {
      exportable = true
      key_size   = 2048
      key_type   = "RSA"
      reuse_key  = true
    }


    secret_properties {
      content_type = "application/x-pkcs12"
    }


  }


}

复制证书Variable.tf

variable "source_key_vault_id" {
  type    = string
}
variable "source_key_vault_cert_name" {
  type    = string
}

variable "destination_key_vault_id" {
  type    = string
}

variable "destination_key_vault_cert_name" {
  type    = string
}

Answer 1

由于您正在使用 resource "azurerm_key_vault" 创建新的密钥保管库，因此您无法使用数据源查询当时在模块 module "Cert1" 和 module "Cert2" 在同一个 .tf 文件中。 data "azurerm_key_vault" 用于访问有关现有 Key Vault 的信息。

所以将文件Resource.tf中的相关代码改成这样：

# data "azurerm_key_vault" "New" {
#   name                = "KV1"
#   resource_group_name = "${var.prefix}-resourceGB"
# }

module "Cert1" {
  source = "../module/copy_cert"
  source_key_vault_id = data.azurerm_key_vault.existing.id
  source_key_vault_cert_name = "Cert1"
  destination_key_vault_id = azurerm_key_vault.New.id     # changed
  destination_key_vault_cert_name = "Cert1"

}
module "Cert2" {
  source = "../module/copy_cert"
  source_key_vault_id = data.azurerm_key_vault.existing.id
  source_key_vault_cert_name = "Cert2"
  destination_key_vault_id = azurerm_key_vault.New.id      # changed
  destination_key_vault_cert_name = "Cert2"

}

面对 Terraform KeyVault 证书创建问题

Facing Terraform KeyVault Certificates creation issue

terraform

azure-keyvault

terraform-provider-azure