使用 Mule 中的 Dataweave 将定界文件转换为 JSON 格式

Question

我需要在 mule 中使用 dataweave 将现有的分隔符文件转换为 json 格式。

示例输入：

Name~#~ID~#~Company~#~Address
SRI~#~1~#~Infy~#~Bangalore
Rahul~#~2~#IBM~#~US
John~#~3~#~SF~#~UK

样本输出

{
Name: Sri
ID: 1
Company: Infy
Adress: Bangalore
},
{
Name: Rahul
ID: 2
Company: IBM
Adress: US

},
{
Name: John
ID: 3
Company: SF
Adress: UK
}

但我的输出低于输出

Dataweave 转换

Answer 1

使用以下输入 (input.txt)：

Name~#~ID~#~Company~#~Address
SRI~#~1~#~Infy~#~Bangalore
Rahul~#~2~#~IBM~#~US
John~#~3~#~SF~#~UK

以及以下 DataWeave 代码：

%dw 2.0
output application/json

var payload = readUrl("classpath://input.txt","text/plain") splitBy(/\r\n/)

var header= payload[0] splitBy(/~#~/)
var data  = payload[1 to -1]
---
data map (item, index) ->
    {(item splitBy(/~#~/) map
    {   
        (header[$$]): $ 
    })}

结果是：

[
  {
    "Name": "SRI",
    "ID": "1",
    "Company": "Infy",
    "Address": "Bangalore"
  },
  {
    "Name": "Rahul",
    "ID": "2",
    "Company": "IBM",
    "Address": "US"
  },
  {
    "Name": "John",
    "ID": "3",
    "Company": "SF",
    "Address": "UK"
  }
]

我推荐一个数组作为输出

Answer 2

非常有趣的问题，您可以使用 dw::core::Binaries 中的 readLines 函数，然后按 ~#~ 拆分。请记住将您的负载设置为 application/octet-stream mimeType，以便 dw 将其作为二进制数据处理，稍后您可以使用此代码段来解析它。

%dw 2.0
output application/json
import dw::core::Binaries
var lines = Binaries::readLinesWith(payload, "UTF-8")


---
lines match {
    case [x ~ xs] -> do {
        var header = x splitBy  "~#~"
        ---
        xs map ((item, index) -> {
              (item splitBy "~#~" map (column, index) -> {
                  (header[index]): column
              } )
        })
    }
}

使用 Mule 中的 Dataweave 将定界文件转换为 JSON 格式

Convert Delimiter fille to JSON format using Dataweave in Mule

json

flat-file

mule

dataweave