无法解析 class org.jenkinsci.plugins.workflow.support.steps.build.DownstreamFailureCause

Question

我有以下build.gradle.kts



plugins {
  id("com.mkobit.jenkins.pipelines.shared-library") version "0.10.1"
  id("com.github.ben-manes.versions") version "0.21.0"
  java
}

java {
  sourceCompatibility = JavaVersion.VERSION_1_8
  targetCompatibility = JavaVersion.VERSION_1_8
}

tasks.withType<Test> {
  this.testLogging {
    this.showStandardStreams = true
  }
}

val log4jVersion = "2.11.2"
val slf4jVersion = "1.7.26"
val declarativePluginsVersion = "1.3.9"

dependencies {
  // logging stuffs
  testImplementation("org.slf4j:slf4j-api:$slf4jVersion")
  testImplementation("org.apache.logging.log4j:log4j-api:$log4jVersion")
  testImplementation("org.apache.logging.log4j:log4j-core:$log4jVersion")
  testImplementation("org.apache.logging.log4j:log4j-slf4j-impl:$log4jVersion")
  testImplementation("org.apache.logging.log4j:log4j-jul:$log4jVersion")

  // general testing stuff
  testImplementation("org.assertj:assertj-core:3.12.2")
  testImplementation("com.lesfurets:jenkins-pipeline-unit:1.3")
  testImplementation("junit:junit:4.12") // TODO: update to 5

  // jenkins specific deps
  testImplementation("org.jenkins-ci.plugins:pipeline-build-step:2.9")
  testImplementation("org.jenkinsci.plugins:pipeline-model-api:$declarativePluginsVersion")
  testImplementation("org.jenkinsci.plugins:pipeline-model-declarative-agent:1.1.1")
  testImplementation("org.jenkinsci.plugins:pipeline-model-definition:$declarativePluginsVersion")
  testImplementation("org.jenkinsci.plugins:pipeline-model-extensions:$declarativePluginsVersion")
  testImplementation("org.jenkins-ci.plugins.workflow:workflow-cps-global-lib:2.8")
  testImplementation("org.jenkins-ci.plugins.workflow:workflow-step-api:2.18")
}

jenkinsIntegration {
  baseUrl.set(uri("http://localhost:5050").toURL())
  authentication.set(providers.provider { com.mkobit.jenkins.pipelines.http.AnonymousAuthentication })
  downloadDirectory.set(layout.projectDirectory.dir("jenkinsResources"))
}

sharedLibrary {
  coreVersion.set(jenkinsIntegration.downloadDirectory.file("core-version.txt").map { it.asFile.readText().trim() })
  pluginDependencies {
    dependency("org.jenkins-ci.plugins", "pipeline-build-step", "2.9")
    dependency("org.jenkinsci.plugins", "pipeline-model-api", declarativePluginsVersion)
    dependency("org.jenkinsci.plugins", "pipeline-model-declarative-agent", "1.1.1")
    dependency("org.jenkinsci.plugins", "pipeline-model-definition", declarativePluginsVersion)
    dependency("org.jenkinsci.plugins", "pipeline-model-extensions", declarativePluginsVersion)
    dependency("org.jenkins-ci.plugins.workflow", "workflow-step-api", "2.18")
  }
}

当我做 gradlew 构建时

我的 groovy 文件之一出现以下错误：

unable to resolve class org.jenkinsci.plugins.workflow.support.steps.build.DownstreamFailureCause

对我来说，依赖关系应该在 pluginDependencies 部分解决。

Answer 1

我找到了解决方案。

我遇到的问题 class 似乎是在版本 2.10

中引入的

所以你需要改变

org.jenkins-ci.plugins:pipeline-build-step:2.9

至

org.jenkins-ci.plugins:pipeline-build-step:2.10

无法解析 class org.jenkinsci.plugins.workflow.support.steps.build.DownstreamFailureCause

unable to resolve class org.jenkinsci.plugins.workflow.support.steps.build.DownstreamFailureCause

groovy

gradle

maven

jenkins

jenkins-pipeline