SAS中PROC MIXED的随机重复语句

Question

我正在学习 SAS 中的 PROC MIXED，以了解如何使用简单的重复数据（pre，post）使用随机和重复语句。我查了很多类似的问题，但我还是个初学者，所以有以下两个问题。请给我一些建议。

1.About配对测试，会出现两种情况，subject(id)作为“固定效应”或者在后面的简单重复数据（pre,post）中作为“随机效应”。我经常看到它是“固定效应”，一般来说，这就是理论？为什么？

2.In下面这种情况，把“随机”和“重复”放在一起不对？我该怎么办？

2021.3.21 我编辑了以下程序。我得到了这样的结果“随机=重复”。但是对于“随机+重复”，我是看不懂的。这也是正确的吗？无论如何，id在这种情况下是没有变化的，所以它不会影响模型？

/* data */
data dt00;
 input id x y;
 cards;
1 1 2
2 1 2
3 1 3
4 1 3
5 1 3
6 1 4
7 1 4
1 2 15
2 2 9
3 2 13
4 2 10
5 2 7
6 2 11
7 2 5 
;
run;

title "random";
proc mixed data = dt00 covtest;* REML ;
 parms/nobound;
 class x id;
 model y = x / ddfm = kr2;
 random id;
*        Estimate    SE       Z      Pr Z;
*id      -1.3333   2.5757  -0.52    0.6047;
*Residual 7.5000   4.3301   1.73    0.0416;
* DF    F      Pr F;
* 6   　22.87   0.0031;

title "repeated";
proc mixed data = dt00 covtest;* REML ;
 class x id;
 model y = x / ddfm = kr2 ;
 repeated x / subject = id type = cs; 
run;
*        Estimate    SE       Z      Pr Z; 
*id      -1.3333   2.5757  -0.52    0.6047;
*Residual 7.5000   4.3301   1.73    0.0416; 
* DF    F      Pr F;
* 6   　22.87   0.0031;

title "random + repeated";
proc mixed data = dt00 covtest;* REML ;
 parms/nobound;
 class x id;
 model y = x / solution ddfm = kr2 ;
 random id;
 repeated x / subject = id type = cs; 
run;
*        Estimate    SE       Z      Pr Z; 
*id       0.1117   2.5757   0.04    0.4827; 
*CS      -1.4451   0        .       .; 
*Residual 7.5000   4.3301   1.73    0.0416; 
* DF    F      Pr F;
* 6   　22.87   0.0031;

title "fixed effect";
proc mixed data = dt00 covtest;* REML ;
 class x id;
 model y = x id / solution ddfm = kr2 ;
run;
*        Estimate    SE       Z      Pr Z; 
*Residual 7.5000   4.3301   1.73    0.0416 ;
* DF    F      Pr F;
* 6   　22.87   0.0031;

title "paired ttest";
proc sort data = dt00; by id; run;
proc transpose data = dt00 out = dt01;
 by id;
 id x;
 var y;
run;
data dt02; set dt01; diff = _2 - _1; run;

proc ttest data = dt02 alpha = 0.05;
 paired _1 * _2;
run;
* DF    T      Pr T;
* 6   -4.78   0.0031;

Answer 1

当您指定 RANDOM patient 时，您是说患者（不同的人）之间的协方差为 0。（如果没有另一个分组会使患者更相似，这很好）。

在 PROC MIXED 中，您可以将患者作为固定因素包括在内，但这通常会使用大部分自由度。相反，如果您将患者视为一个随机因素，您仍然控制着每个人，但您使用的自由度较低。

如果有额外的非独立性（甚至是非恒定方差），你仍然可以通过添加一个重复语句来估计那些非零协方差。因此，包含一个 REPEATED 语句和一个 RANDOM 语句是很好的，有时对于一个好的拟合模型是必要的。重复语句控制单个主题的残差的协方差结构。

每个人都从某个地方开始，所以不要担心。

SAS中PROC MIXED的随机重复语句

Random and Repeated statement of PROC MIXED in SAS

sas

mixed-models