使用 hyperlink 到 link 到 outlook 邮件中的文档

Question

我试图使用以下代码向打开的文档插入“单击此处”link 到 link，但我遇到了问题。

在起草电子邮件并插入 link 后，只有部分 hyperlink 被转移到电子邮件中，这意味着 hyperlink 不起作用.

我正在尝试执行以下操作：

Private Sub Completion_Notification()

Dim xInspect As Object
Dim pageEditor As Object
Dim Strbody As String
Dim CommentsPath As String
Dim CommentsName As String

CommentsName = ActiveWorkbook.Name
CommentsPath = Application.ActiveWorkbook.FullName

Strbody = "<A href=" & Application.ActiveWorkbook.FullName & ">Click Here</A>"

'Getting the email List
Dim i As Integer
Dim Email_Rng As Range
Dim Num_of_Emails As Integer

         
            Dim OutApp As Object
            Dim OutMail As Object
            
            Set OutApp = CreateObject("Outlook.Application")
            Set OutMail = OutApp.CreateItem(0)
            
                With OutMail
                
                .To = "Email"
                .CC = ""
                .Subject = "Email_Subject"
                .HTMLBody = "<html><p>Hi, " & "</p>" & _
                 "<p>" & Strbody & _
                "<p>" & "Many Thanks"

                    .Display
                    '.Send
        
                End With
        
        On Error GoTo 0
        
        Set OutMail = Nothing
        Set OutApp = Nothing

End Sub

但是，当我进入代码并检查“strbody”表达式的值时，link 是完整的，所以我不知道为什么这不起作用。可以插入 href 的字符数是否有限制？

Answer 1

要将 link 表示为本地文件，请使用 <A HREF=""file://

例子

Option Explicit
Public Sub example()

    Dim Strbody As String
        Strbody = "<A HREF=""file://" & _
                    Application.ActiveWorkbook.FullName & _
                    """>Click Here</A>"
    
    
    Dim OutApp As Object
    Set OutApp = CreateObject("Outlook.Application")
    Dim OutMail As Object
    Set OutMail = OutApp.CreateItem(0)
    
    With OutMail
        .HTMLBody = "<html><p>Hi, " & "</p>" & _
        "<p>" & Strbody & _
        "<p>" & "Many Thanks"
        
        .Display
        '.Send
    End With
    
End Sub

使用 hyperlink 到 link 到 outlook 邮件中的文档

Using a hyperlink to link to a document in an outlook mail

outlook

vba