Excel解析地址字符数限制

Question

我目前正在解析地址。我唯一的要求是每个地址单元格（地址 1、地址 2、地址 3 等）中的字符不应超过 40 个。问题是地址都有不同的格式，我想防止单词在中间被切断。地址示例（在 G 列中）： Naaaaaaaaaaaaaaaaaaaaaaame, 342 Streeeeeet, city, 452342 邮编, Country 这就是我的进展：

Adress3=IF(LEN(G3)>40;RIGHT(G3;LEN(G3)-FIND("*";SUBSTITUTE(G3;" ";"*";LEN(G3)-LEN(SUBSTITUTE(G3;" ";"")))));"")

Adress1==IF(I3<>""; IF(RIGHT(IF(I3<>"";TRIM(SUBSTITUTE(G3; I3; "")); G3);1)=",";LEFT(IF(I3<>"";TRIM(SUBSTITUTE(G3; I3; "")); G3);LEN(IF(I3<>"";TRIM(SUBSTITUTE(G3; I3; "")); G3))-1);IF(I3<>"";TRIM(SUBSTITUTE(G3; I3; "")); G3)); IF(I3<>"";TRIM(SUBSTITUTE(G3; I3; "")); G3))

这行得通，但是我需要找到一种方法来多次执行此操作（因为有些地址真的很长），这样我就会得到类似的东西：

地址 1：40 个字符

地址 2：40 个字符

地址3：剩余字符

有没有不用VBA解决这个问题的方法？我希望我说得有道理，如果有任何建议，我将不胜感激！！

Answer 1

这三个渐进公式似乎适用于您的单个示例。

G5:K5中的公式为：

=TRIM(LEFT(SUBSTITUTE(G3, " ", REPT(" ", 99), 40-LEN(SUBSTITUTE(LEFT(G3, 40), " ", ""))), 40))
=IFERROR(TRIM(LEFT(SUBSTITUTE(MID(G3, LEN(G5&REPT(" ", 1)), 40), " ", REPT(" ", 99), 40-LEN(SUBSTITUTE(LEFT(MID(G3, LEN(G5&REPT(" ", 1)), 40), 40), " ", ""))), 40)), "")
=IFERROR(TRIM(LEFT(SUBSTITUTE(MID(G3, LEN(G5&H5&REPT(" ", 2)), 40), " ", REPT(" ", 99), 40-LEN(SUBSTITUTE(LEFT(MID(G3, LEN(G5&H5&REPT(" ", 2)), 40), 40), " ", ""))), 40)), "")
=IFERROR(TRIM(LEFT(SUBSTITUTE(MID(G3, LEN(G5&H5&I5&REPT(" ", 3)), 40), " ", REPT(" ", 99), 40-LEN(SUBSTITUTE(LEFT(MID(G3, LEN(G5&H5&I5&REPT(" ", 3)), 40), 40), " ", ""))), 40)), "")
=IFERROR(TRIM(LEFT(SUBSTITUTE(MID(G3, LEN(G5&H5&I5&J5&REPT(" ", 4)), 40), " ", REPT(" ", 99), 40-LEN(SUBSTITUTE(LEFT(MID(G3, LEN(G5&H5&I5&J5&REPT(" ", 4)), 40), 40), " ", ""))), 40)), "")

请注意，H5 中的公式取决于 G5 中的结果，I5 中的公式取决于 H5 和 G5 中的结果。

不确定您可能想用 H5 中的尾随逗号做什么。

Excel解析地址字符数限制

Excel parse address character limit

excel

parsing

limit

maxlength

excel-formula