使用 XSLT 的 CDATA XML 掩码应该 return 相同 XML，只有很少的掩码字段

Question

我需要使用 XSLT 屏蔽 XML 内 CDATA XML 中的几个字段。
因此结果 XML 应该与输入 XML 相同，但很少有文件被 XSLT 屏蔽。
我按照 this link 进行了掩码，但生成的 XML 格式不同。
我尝试了 SO 的许多其他解决方案，它们几乎以不同于输入 XML.
的其他格式输出新的 XML/HTML 请检查以下示例以获得更好的理解。
输入 XML 和 CDATA 内容。

<XML>
  <LogLevel>info</LogLevel>
  <Content><![CDATA[ <Msg>
        <AccountNo>2701000098983</AccountNo>
        <ApplName>Testing</ApplName>
       </Msg>]]></Content>
  <Date>20140909</Date>
</XML>

输出 XML 应该是：

   <XML>
      <LogLevel>info</LogLevel>
      <Content><![CDATA[ <Msg>
            <AccountNo>XXXXXXXXXX983</AccountNo>
            <ApplName>Testing</ApplName>
           </Msg>]]></Content>
      <Date>20140909</Date>
   </XML>

编辑：
我使用了以下 XSLT

 <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
    <xsl:template match="text()">
        <xsl:choose>
            <xsl:when test="contains(.,'&lt;AccountNo&gt;')">
                <!-- This is the CDATA that I want to mask and write back out as CDATA -->
                <xsl:variable name="tcontent">
                    <xsl:value-of
                        select="substring-after(substring-before(.,'&lt;/AccountNo&gt;'),'&lt;AccountNo&gt;') " />
                </xsl:variable>
                <xsl:text disable-output-escaping="yes">&lt;![CDATA[&lt;AccountNo&gt;</xsl:text>
                <xsl:call-template name="maskVariable">
                    <xsl:with-param name="tvar" select="$tcontent" />
                </xsl:call-template>
                <xsl:text disable-output-escaping="yes">&lt;/AccountNo&gt;]]&gt;</xsl:text>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
<xsl:template name="maskVariable">
    <xsl:param name="tvar" />
    <xsl:variable name="length" select="string-length($tvar)" />
    <xsl:choose>
        <xsl:when test="$length > 3">
            <xsl:value-of
                select="concat ('************', substring($tvar,$length - 1, 2))" />
        </xsl:when>
        <xsl:when test="$length > 1">
                ***
            </xsl:when>
            <xsl:otherwise />
        </xsl:choose>
    </xsl:template>

使用此 XSLT 的输出是：

<LogLevel>info</LogLevel>
<Content><![CDATA[<AccountNo>************02</AccountNo>]]></Content>
<Date>20140909</Date>

这里的输出，只显示被屏蔽的输出。
如何使代码的其他部分显示出来？请告诉我如何做？
非常感谢任何帮助。

Answer 1

你为什么不试试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Content">
    <xsl:copy>
        <xsl:value-of select="substring-before(.,'&lt;AccountNo&gt;')" />
        <xsl:text>&lt;AccountNo&gt;</xsl:text>
        <xsl:variable name="acct-num" select="substring-before(substring-after(.,'&lt;AccountNo&gt;'), '&lt;/AccountNo&gt;')" />
        <xsl:value-of select="concat('************', substring($acct-num, string-length($acct-num) - 2))" />
        <xsl:text>&lt;/AccountNo&gt;</xsl:text>
        <xsl:value-of select="substring-after(.,'&lt;/AccountNo&gt;')" />
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

应用于您的输入，结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<XML>
   <LogLevel>info</LogLevel>
   <Content> &lt;Msg&gt;
        &lt;AccountNo&gt;************983&lt;/AccountNo&gt;
        &lt;ApplName&gt;Testing&lt;/ApplName&gt;
       &lt;/Msg&gt;</Content>
   <Date>20140909</Date>
</XML>

或者，您可以使用：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" cdata-section-elements="Content"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Content">
    <xsl:copy>
        <xsl:variable name="content">
            <xsl:value-of select="substring-before(.,'&lt;AccountNo&gt;')" />
            <xsl:text>&lt;AccountNo&gt;</xsl:text>
            <xsl:variable name="acct-num" select="substring-before(substring-after(.,'&lt;AccountNo&gt;'), '&lt;/AccountNo&gt;')" />
            <xsl:value-of select="concat('************', substring($acct-num, string-length($acct-num) - 2))" />
            <xsl:text>&lt;/AccountNo&gt;</xsl:text>
            <xsl:value-of select="substring-after(.,'&lt;/AccountNo&gt;')" />
        </xsl:variable>
        <xsl:value-of select="$content" disable-output-escaping="yes"/> 
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

生产：

<?xml version="1.0" encoding="UTF-8"?>
<XML>
<LogLevel>info</LogLevel>
<Content><![CDATA[ <Msg>
        <AccountNo>************983</AccountNo>
        <ApplName>Testing</ApplName>
       </Msg>]]></Content>
<Date>20140909</Date>
</XML>

尽管这可能不适用于每个处理器（经测试可与 Xalan 2.7.1 一起使用：http://xsltransform.net/jyH9rMk）。

Answer 2

CDATA 部分中的内容 XML 伪装成文本。 XSLT擅长转换XML，但不太擅长转换文本，尤其是语法复杂的文本。所以我的方法是：从外部 XML 文档中提取文本，将其解析为 XML，使用 XSLT（适用于节点而不是标记的真正 XSLT）对其进行转换，将其序列化回文本，然后将文本塞回原始（外部）XML 文档。

Raw XSLT 1.0 无法在单个样式表中执行此操作。您需要函数 parse() 和 serialize() 将词法 XML 转换为节点树，然后再返回。它们在某些处理器（例如 Saxon）中作为扩展可用，它们在 XPath 3.0 中作为标准函数可用，并且它们可以在大多数其他处理器中编写为简单的扩展函数（例如在 Javascript 中）代码。

使用 XSLT 的 CDATA XML 掩码应该 return 相同 XML，只有很少的掩码字段

CDATA XML masking with XSLT should return same XML with few masked fields

java

xml

xslt