使用 XSLT 过滤源 XML 到目标 XML

Question

由于生产问题，大量数据已损坏。好消息是我将所有数据都放在一个 XML 文件中，该文件恰好与提交数据更改的输入格式相同。我遇到的问题是处理一条记录需要一段时间。我的 "clean master" 有超过 20,000 条记录，只有 530 条已损坏。我有一个关键字段来标识要包含在目的地中的记录。我如何才能包含在 XSLT 中以仅在我指定的列表中输出节点？我不在乎是否在 XSLT 中对列表进行硬编码。

<recordSet>
  <record>
    <key>123</key>
    <val1>abc</val1>
    <val2>def</val2>
   </record>
  <record>
    <key>456</key>
    <val1>hij</val1>
    <val2>klm</val2>
   </record>
  <record>
    <key>789</key>
    <val1>nop</val1>
    <val2>qrs</val2>
   </record>
 </recordSet>

假设我只想要密钥为 123 和密钥 789 的记录。谢谢。

Answer 1

I do not care if I hard-code the list in the XSLT.

以下是如何在 XSLT 1.0 中高效优雅地完成此操作：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:variable name="keys">
    <key>123</key>
    <key>789</key>
</xsl:variable>

<xsl:key name="record" match="record" use="key" />

<xsl:template match="/recordSet">
    <xsl:copy>
        <xsl:copy-of select="key('record', exsl:node-set($keys)/key)"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

在 XSLT 2.0 中，这可以简化为：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:variable name="keys">
    <key>123</key>
    <key>789</key>
</xsl:variable>

<xsl:key name="record" match="record" use="key" />

<xsl:template match="/recordSet">
    <xsl:copy>
        <xsl:copy-of select="key('record', $keys/key)"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

使用 XSLT 过滤源 XML 到目标 XML

Use XSLT to filter source XML to destination XML

xml

xslt