XSLT select 按子节点值

Question

我正在尝试使用 XSLT 处理一个 XML 文件，我需要在其中按子值处理 select 个节点。我试图通过正则表达式简单地过滤掉结果，但也许这不是最优雅的方法。我认为 XSLT 是进行此转换的通用解决方案，如果不是请建议我更好的解决方案。 XML 文件实际上是这样的：

<?xml version="1.0" encoding="windows-1250"?>
<SHOP>
<SHOPITEM>
<unknown_element1></unknown_element1>
<unknown_element2></unknown_element2>
...
<YEAR>2015</YEAR>
<unknown_elementxy></unknown_elementxy>
...
</SHOPITEM>
<SHOPITEM>
<unknown_element1></unknown_element1>
<unknown_element2></unknown_element2>
...
<YEAR>2014</YEAR>
<unknown_elementxy></unknown_elementxy>
...
</SHOPITEM>
<SHOPITEM>
<unknown_element1></unknown_element1>
<unknown_element2></unknown_element2>
...
<YEAR>2015</YEAR>
<unknown_elementxy></unknown_elementxy>
...
</SHOPITEM>
</SHOP>

我想保留当前的 XML 结构，但只保留 = 2015 的节点。所需的输出：

<?xml version="1.0" encoding="windows-1250"?>
<SHOP>
<SHOPITEM>
<unknown_element1></unknown_element1>
<unknown_element2></unknown_element2>
...
<YEAR>2015</YEAR>
<unknown_elementxy></unknown_elementxy>
...
</SHOPITEM>
<SHOPITEM>
<unknown_element1></unknown_element1>
<unknown_element2></unknown_element2>
...
<YEAR>2015</YEAR>
<unknown_elementxy></unknown_elementxy>
...
</SHOPITEM>
</SHOP>

<unknown_element> = 节点中有许多不同的元素，XSLT 应保持实际节点的当前结构。只需要通过<YEAR>.

过滤掉节点

我正在尝试这样的事情：

<?xml version="1.0" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="no" indent="yes" method="xml"/>

 <xsl:template match="//SHOPITEM[YEAR=2015]">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

</xsl:stylesheet>

Answer 1

您可以嵌套谓词 - 尝试 //SHOPITEM[YEAR[text() = 2015]]

Answer 2

正如 Ian Roberts 所说，您应该从身份转换开始，然后从那里进行自定义。这就是您所需要的：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="no" indent="yes" method="xml"/>

 <xsl:template match="node() | @*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <!-- Omit any shop item without YEAR = 2015 -->
 <xsl:template match="SHOPITEM[not(YEAR = 2015)]" />

</xsl:stylesheet>

当您的示例输入运行时，结果为：

<SHOP> 
  <SHOPITEM> 
    <unknown_element1/>  
    <unknown_element2/> ...
    <YEAR>2015</YEAR>  
    <unknown_elementxy/> ...
  </SHOPITEM>  

  <SHOPITEM> 
    <unknown_element1/>  
    <unknown_element2/> ...
    <YEAR>2015</YEAR>  
    <unknown_elementxy/> ...
  </SHOPITEM> 
</SHOP>

Answer 3

这对你有用吗？

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/SHOP">
    <xsl:copy>
        <xsl:copy-of select="SHOPITEM[YEAR=2015]"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

XSLT select 按子节点值

XSLT select by child node value

xml

xslt