如何在使用 WinRAR 创建多个 ZIP 压缩文件时显示丢失文件列表和其他错误？

Question

我创建了这个批处理文件来创建基于文本文件的 ZIP 文件：

@echo off

set path="C:\Program Files\WinRAR\";%path%

for /f "tokens=1* delims=;" %%a in (list.txt) do (
    WinRAR a -afzip "%%a" %%b
    pause
    cls
)

文件 list.txt 如下所示：

file1.zip;fileA.pdf fileB.pdf fileC.pdf
file2.zip;fileA.pdf fileB.pdf fileC.pdf fileD.pdf
file3.zip;fileB.pdf fileD.pdf
file4.zip;fileA.pdf fileC.pdf fileE.pdf
file5.zip;file*.pdf

如您所见：

%%a 是要创建的 ZIP 文件的名称，例如：file1.zip 和
%%b 是要添加到 ZIP 文件的文件列表，例如：fileA.pdf fileB.pdf fileC.pdf for file1.zip.

它工作得很好，但我想知道是否可以让我显示哪些文件它无法找到（因此没有添加到 ZIP 文件）创建的每个 ZIP 文件。

有什么想法吗？

编辑： 如@Mofi 所述，Rar 不能用于创建 ZIP 文件。所以我改变了

    rar a -r -m5 "%%a" %%b

至

    WinRAR a -afzip "%%a" %%b

Answer 1

....
for /f "tokens=1* delims=;" %%a in (list.txt) do ( 

   for %%f in (%%b) do if not exist %%f echo %%f does not exist

   WinRAR a -afzip "%%a" %%b
 ....

应该会显示丢失的文件。

实际代码运行验证：

@ECHO OFF
SETLOCAL
PUSHD "u:\sourcedir\t w o"
dir
ECHO ---------------------------------

FOR /f "tokens=1*delims=;" %%a IN (c:q33944403.txt) DO (
   for %%f in (%%b) do if not exist %%f echo %%f does not EXIST
   ECHO yourcompressor options "%%a" %%b
   ECHO ---------------------------------
)

popd

GOTO :EOF

结果：

 Directory of u:\sourcedir\t w o

28/11/2015  01:01    <DIR>          .
28/11/2015  01:01    <DIR>          ..
28/11/2015  01:05                 0 dum myfile2.txt
28/11/2015  01:05                 0 file1.zip
28/11/2015  01:05                 0 fileA.pdf
28/11/2015  01:05                 0 fileB.pdf
28/11/2015  01:05                 0 file2.zip
28/11/2015  01:05                 0 fileD.pdf
28/11/2015  01:05                 0 file3.zip
28/11/2015  01:05                 0 file4.zip
28/11/2015  01:05                 0 fileE.pdf
               9 File(s)              0 bytes
               2 Dir(s)   2,134,933,504 bytes free
---------------------------------
fileC.pdf does not EXIST
yourcompressor options "file1.zip" fileA.pdf fileB.pdf fileC.pdf
---------------------------------
fileC.pdf does not EXIST
yourcompressor options "file2.zip" fileA.pdf fileB.pdf fileC.pdf fileD.pdf
---------------------------------
yourcompressor options "file3.zip" fileB.pdf fileD.pdf
---------------------------------
fileC.pdf does not EXIST
yourcompressor options "file4.zip" fileA.pdf fileC.pdf fileE.pdf
---------------------------------

评论：

目录"u:\sourcedir\t w o\"只是一个测试目录。请注意，它包含 OP 列表中除 FileC.pdf

之外的所有文件

Pushd/popd 简单地导航到该目录并返回。

我用作数据源的文件（OP 的 list.txt）是 c:q33944403.txt，其中包含与运行报告中报告的相同数据。

所以 - 它非常适合我！

Answer 2

主机版 Rar 不支持 ZIP 格式，因为它可以在文本文件 %ProgramFiles%\WinRAR\Rar.txt 中读取，这是主机版的手册。只有 GUI 版本 WinRAR 支持创建和提取 ZIP 存档。

在使用 WinRAR 时无需单独测试所有要归档的文件是否存在，如注释批处理代码所示：

@echo off
rem Define name of error log file in directory for temporary files with name
rem of batch file, an underscore, a random number and file extension TMP.
set "ErrorLog=%TEMP%\%~n0_%RANDOM%.tmp"

rem Delete error log file if already existing from a previous run of this
rem batch file broke by the user while running and having randomly the
rem same number.
if exist "%ErrorLog%" del "%ErrorLog%"

rem For each ZIP file run WinRAR with ignoring default configuration (-cfg-)
rem using best compression (-m5), running in background (-ibck = minimized
rem to system tray), writing error messages into a log file (-ilog) and
rem suppressing displaying the errors in a GUI window (-inul).

rem If WinRAR really output any error into the log file, clear screen, output
rem on which ZIP file the error(s) occurred, output the logged error messages,
rem delete the error log file, and hold batch processing until user presses
rem any key to continue.

for /f "tokens=1* delims=;" %%a in (list.txt) do (
    "%ProgramFiles%\WinRAR\WinRAR.exe" a -afzip -cfg- -m5 -ibck "-ilog%ErrorLog%" -inul -- "%%~a" %%b
    if exist "%ErrorLog%" (
        cls
        echo Errors output by WinRAR on creating %%a:
        echo.
        type "%ErrorLog%"
        del "%ErrorLog%"
        echo.
        echo.
        pause
    )
)

rem Delete the environment variable for error log file name with path.
set "ErrorLog="

有关使用的 WinRAR 开关的更多详细信息

启动WinRAR,
单击菜单帮助 帮助主题，
在选项卡上打开内容项目 命令行模式,
打开项目开关和
单击上面批处理代码中使用的开关（选项/参数）。

重要的是不要使用 -r 开关（递归），因为这意味着 WinRAR 压缩文件名称后的参数可以是文件或目录。

WinRAR v5.21 不报告压缩时不存在的目录，只报告因为根本不存在或没有读取权限而无法打开读取的文件（NTFS partition) for current user, or read/write lock set by other 运行 process on file, etc. 操作系统返回文件打开错误的原因也由 WinRAR 关于文件打开失败的错误消息。

WinRAR 期望没有 -r 压缩文件名后的每个参数都是文件名（有或没有路径），因此如果无法打开文件读取数据。

但参数也可以是使用开关 -r 时不存在的目录名称，WinRAR.

不会将其报告为错误

如果列表文件中的一个或多个文件包含 1 个或多个空格或这些字符之一

&()[]{}^=;!'+,`~

在文件名中需要在列表文件中引用此文件名。

示例：

"file 1.zip";"file A.pdf" fileB.pdf "file C.pdf"
file 2.zip;"file A.pdf" fileB.pdf "file C.pdf" fileD.pdf
file3.zip;fileB.pdf fileD.pdf
file4.zip;"fileA.pdf" fileC.pdf fileE.pdf
file5.zip;file*.pdf
file6.zip;file*.pdf readme.txt

由于在命令行调用 WinRAR.

时使用 "%%~a"，压缩文件名也可以不带引号

最后两行表明也可以使用具有 1 个或多个通配符的文件名模式。但是错误消息 No files to add 仅在由于找不到要添加的文件而无法创建 ZIP 文件时才由 WinRAR 输出。因此，如果没有 file*.pdf，第 5 行会产生错误消息，但如果至少存在 readme.txt 并且可以添加到存档文件，第 6 行不会产生错误消息。

WinRAR 根据页面 WinRAR 退出代码列表 在 [=67= 的帮助下也设置 errorlevel 退出]WinRAR。但是，如果在任何情况下都输出错误消息，则评估批处理文件中的退出代码没有多大意义。错误日志文件仅在发生任何错误时由 WinRAR 创建。

最后但同样重要的是，还可以使用开关 -log 将添加到存档中的文件的名称写入日志文件，并使用 type 和 [= 输出这些列表26=] 在控制台中 window。有关开关 -log.

的详细信息，请参阅 WinRAR 的帮助

要了解使用的控制台命令及其工作原理，请打开命令提示符 window，在其中执行以下命令，并仔细阅读为每个命令显示的所有帮助页面。

cls /?
del /?
echo /?
for /?
if /?
pause /?
rem /?
set /?
type /?

如何在使用 WinRAR 创建多个 ZIP 压缩文件时显示丢失文件列表和其他错误？

How to show list of missing files and other errors on creating multiple ZIP archives with WinRAR?

windows

batch-file

cmd

winrar