Hive 根据文件名创建 Table 个分区

Question

Hadoop 新手。我知道如何在 Hive 中创建 table （语法）创建具有 3 个分区键的 table。但密钥在文件名中。

文件名示例：ServerName_ApplicationName_ApplicationName.XXXX.log.YYYY-MM-DD

一个目录中有数百个文件想要创建一个 table 并使用文件名中的以下分区键：ServerName、ApplicationName、Date 并将所有文件加载到 table Hive Script 是首选，但对任何其他想法持开放态度

（文件是 CSV。我知道文件的架构（列定义））

Answer 1

我假设文件名的格式为 ServerName_ApplicationName.XXXX.log.YYYY-MM-DD（删除第二个 "applicationname"，假设它是错字）。

在原始文件的内容上创建一个 table。有些东西像..

create external table default.stack
(col1 string,
 col2 string,
 col3 string,
 col4 int,
 col5 int
 )
 ROW FORMAT DELIMITED
 FIELDS terminated  by ','
 STORED AS INPUTFORMAT                                                  
  'org.apache.hadoop.mapred.TextInputFormat'                           
OUTPUTFORMAT                                                           
  'org.apache.hadoop.hive.ql.io.HiveIgnoreKeyTextOutputFormat' 
 location 'hdfs://nameservice1/location1...';

在另一个位置创建另一个分区 table，例如

create external table default.stack_part
(col1 string,
 col2 string,
 col3 string,
 col4 int,
 col5 int
 )
 PARTITIONED BY ( servername string, applicationname string, load_date string)
 STORED as AVRO  -- u can choose any format for the final file
 location 'hdfs://nameservice1/location2...';

使用以下查询从基 table 插入分区 table：

set hive.exec.dynamic.partition.mode=nonstrict;
SET hive.exec.compress.output=true;
set hive.exec.parallel=true;
SET mapred.output.compression.codec=org.apache.hadoop.io.compress.SnappyCodec;

Insert overwrite table default.stack_part
partition ( servername, applicationname, load_date)
select *, 
       split(reverse(split(reverse(INPUT__FILE__NAME),"/")[0]),"_")[0] as servername
       ,split(split(reverse(split(reverse(INPUT__FILE__NAME),"/")[0]),"_")[1],'[.]')[0] as applicationname
       ,split(split(reverse(split(reverse(INPUT__FILE__NAME),"/")[0]),"_")[1],'[.]')[3] as load_date
from default.stack;

我已经测试过了，它有效。

Hive 根据文件名创建 Table 个分区

Hive Create Table Partitions from file name

hadoop

hive

apache-pig

hiveql

hadoop2