Iex中是否有默认启用千位分组（100_000）的开关

Question

请问在 Iex 中是否有默认启用千位分组的开关（例如 100_000）。如果是，那将是非常有帮助的。

不然怎么在IO.puts中指定呢？

Answer 1

没有根据 Inspect.Opts 描述的启用数字分组的本机选项。

但是，如果将 IEx 与 Integer 和 Float 放在本地 ~/.iex.exs 文件中，则以下内容应该可以覆盖 inspect 的行为：

defmodule PrettyNumericInspect do
  def group(value, :binary, true),
    do: value |> group_by(8)
  def group(value, :decimal, true),
    do: value |> group_by(3)
  def group(value, :hex, true),
    do: value |> group_by(2)
  def group(value, :octal, true),
    do: value |> group_by(4)
  def group(value, _, _),
    do: value

  defp group_by(value, n) when byte_size(value) > n do
    size = byte_size(value)
    case size |> rem(n) do
      0 ->
        (for << << g :: binary-size(n) >> <- value >>,
          into: [],
          do: g)
        |> Enum.join("_")
      r ->
        {head, tail} = value |> String.split_at(r)
        [head, group_by(tail, n)] |> Enum.join("_")
    end
  end
  defp group_by(value, _),
    do: value
end

defimpl Inspect, for: Float do
  def inspect(thing, %Inspect.Opts{pretty: pretty}) do
    [head, tail] = IO.iodata_to_binary(:io_lib_format.fwrite_g(thing))
    |> String.split(".", parts: 2)
    [PrettyNumericInspect.group(head, :decimal, pretty), tail]
    |> Enum.join(".")
  end
end

defimpl Inspect, for: Integer do
  def inspect(thing, %Inspect.Opts{base: base, pretty: pretty}) do
    Integer.to_string(thing, base_to_value(base))
    |> PrettyNumericInspect.group(base, pretty)
    |> prepend_prefix(base)
  end

  defp base_to_value(base) do
    case base do
      :binary  -> 2
      :decimal -> 10
      :octal   -> 8
      :hex     -> 16
    end
  end

  defp prepend_prefix(value, :decimal), do: value
  defp prepend_prefix(value, base) do
    prefix = case base do
      :binary -> "0b"
      :octal  -> "0o"
      :hex    -> "0x"
    end
    prefix <> value
  end
end

Inspect.Opts 选项 :pretty 必须设置为 true 才能显示数字分组。根据 IEx.configure/1 的文档，漂亮检查应该默认启用。

启动 iex 时，您会看到 2 个关于重新定义 Inspect.Float 和 Inspect.Integer 的警告，但之后它应该会继续正常工作：

iex> 100_000
100_000
iex> 100_000.1
100_000.1

它还支持不同 :base 选项（:binary、:decimal、:octal 和 :hex）的分组：

iex> inspect 0b11111111_11111111, base: :binary, pretty: true
"0b11111111_11111111"
iex> inspect 999_999, base: :decimal, pretty: true
"999_999"
iex> inspect 0o7777_7777, base: :octal, pretty: true
"0o7777_7777"
iex> inspect 0xFF_FF, base: :hex, pretty: true
"0xFF_FF"

Iex中是否有默认启用千位分组（100_000）的开关

Is there a Switch to enable thousand digit grouping (100_000) by default in Iex

formatting

elixir

elixir-iex