xslt 去除重复元素

Question

我正在尝试从该文件中删除具有相同 href 属性的元素：

<?xml version="1.0" encoding="UTF-8"?>
<images>
    <item id="d1e152_1" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e163_2" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e174_3" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e218_4" href="Pic/104763.jpg" media-type="image/jpeg"/>
    <item id="d1e349_5" href="Pic/110001.tif" media-type="image/tif"/>
    <item id="d1e681_6" href="Pic/199201.tif" media-type="image/tif"/>
    <item id="d1e688_7" href="Pic/124566.tif" media-type="image/tif"/>
</images>

使用此 xslt 2.0 样式表

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" exclude-result-prefixes="fn xs fo">

<xsl:output method="xml"/>

<xsl:strip-space elements="*"/>

<xsl:template match="/images">
<new_images>
    <xsl:apply-templates/>
    </new_images>
</xsl:template>

<xsl:template match="item">
<xsl:for-each-group select="." group-by="@href">
    <xsl:copy-of select="current-group()[1]"/>
</xsl:for-each-group>
</xsl:template>

</xsl:stylesheet>

这里的预期结果：

<?xml version="1.0" encoding="UTF-8"?>
<new_images>
    <item id="d1e152_1" href="Pic/104764.jpg" media-type="image/jpeg"/>
    <item id="d1e218_4" href="Pic/104763.jpg" media-type="image/jpeg"/>
    <item id="d1e349_5" href="Pic/110001.tif" media-type="image/tif"/>
    <item id="d1e681_6" href="Pic/199201.tif" media-type="image/tif"/>
    <item id="d1e688_7" href="Pic/124566.tif" media-type="image/tif"/>
</new_images>

为什么不起作用？我在生成的 xsl 文件中仍然有所有重复项。

Answer 1

我知道了....我经常遇到...必须将 for-each-group 放在 /images 的模板中...

已更新 XSLT 2.0...

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" exclude-result-prefixes="fn xs fo">

  <xsl:output method="xml"/>

  <xsl:strip-space elements="*"/>

  <xsl:template match="/images">
    <new_images>
      <xsl:for-each-group select="item" group-by="@href">
        <xsl:copy-of select="current-group()[1]"/>
      </xsl:for-each-group>
    </new_images>
  </xsl:template>

</xsl:stylesheet>

Answer 2

这个 XSLT 1.0 解决方案更短而且不慢：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kByHref" match="item" use="@href"/>

  <xsl:template match="/*">
    <new_images>
      <xsl:copy-of select=
      "*[generate-id() = generate-id(key('kByHref', @href)[1])]"/>
    </new_images>
  </xsl:template>
</xsl:stylesheet>

xslt 去除重复元素

xslt remove duplicate elements

xml

saxon

xslt-2.0