寻找“if p x then x else empty”构造的泛化

Question

我有几个片段感觉它们在做同样的事情，但我不完全相信有一个通用的结构来处理它们。在一个地方，我有

ensure :: (String -> Bool) -> String -> String
ensure p x =
    if p x then
        x
    else
        ""

这在使用中可能类似于

ensure (/= "kim") "alex"    -- returns "alex"
ensure (/= "kim") "kim"     -- returns ""

在另一个，我有非常相似的

ensure :: (a -> Bool) -> Maybe a -> Maybe a
ensure p maybeX = do
    x <- maybeX
    if p x then
        Just x
    else
        Nothing

这看起来像

ensure even 6     -- returns Just 6
ensure even 11    -- returns Nothing

两者都根据某些谓词检查值是否正确，如果不正确，它们将返回默认的 "empty" 外观值。虽然有一点不同——这意味着第二个函数可以重写为

ensure :: (Maybe a -> Bool) -> Maybe a -> Maybe a
ensure p maybeX =
    if p x then
        x
    else
        Nothing

为了使它们更相似，将 "unwrapping" 和 Maybe 的责任放在谓词上。有了这个新定义，这两个功能都将归入

ensure :: Alternative f => (f a -> Bool) -> f a -> f a
ensure p x =
    bool x empty (p x)

所以，我的问题是，

这个 bool x empty (p x) 是否以某种形式存在，所以我不必自己实现这个功能？ 内联 bool x empty (p x) 的问题在于我的情况是，p 和 x 都很长。

Answer 1

以下是评论中的建议。一个使用 Monoid，由 9000:

ensure :: Monoid a => (a -> Bool) -> a -> a
ensure p a = if p a then a else mempty

另一个使用 MonadPlus，由 user3237465:

ensure :: MonadPlus m => (a -> Bool) -> a -> m a
ensure p = mfilter p . return

第二个变体只需要 Alternative，来自 Daniel Wagner：

ensure :: Alternative f => (a -> Bool) -> a -> f a
ensure p x = x <$ guard (p x)

Looking for generalisation of the `if p x then x else empty` construct