CUDA/Thrust: 如何对交错数组的列求和？

Question

使用 Thrust 可以直接对交错（即由矢量支持）数组的行求和，如示例 here.[=16= 所示]

我想做的是对数组的列求和。

我尝试使用类似的结构，即：

// convert a linear index to a column index
template <typename T>
struct linear_index_to_col_index : public thrust::unary_function<T,T>
{
  T C; // number of columns

  __host__ __device__
  linear_index_to_col_index(T C) : C(C) {}

  __host__ __device__
  T operator()(T i)
  {
    return i % C;
  }
};

// allocate storage for column sums and indices
thrust::device_vector<int> col_sums(C);
thrust::device_vector<int> col_indices(C);

// compute row sums by summing values with equal row indices
thrust::reduce_by_key
  (thrust::make_transform_iterator(thrust::counting_iterator<int>(0), linear_index_to_col_index<int>(C)),
   thrust::make_transform_iterator(thrust::counting_iterator<int>(0), linear_index_to_col_index<int>(C)) + (R*C),
   array.begin(),
   col_indices.begin(),
   col_sums.begin(),
   thrust::equal_to<int>(),
   thrust::plus<int>());

然而，这只会对第一列求和，其余的将被忽略。我对为什么会发生这种情况的猜测是，如 reduce_by_key docs:

中所述

For each group of consecutive keys in the range [keys_first, keys_last) that are equal, reduce_by_key copies the first element of the group to the keys_output. [Emphasis mine]

如果我的理解是正确的，因为行迭代器中的键是连续的（即索引 [0 - (C-1)] 将给出 0，然后 [C - (2C-1)] 将给出 1 和依此类推），它们最终被加在一起。

但是列迭代器会将索引 [0 - (C-1)] 映射到 [0 - (C-1)] 然后重新开始，索引 [C - (2C-1)] 将映射到[0 - (C-1)] 等使产生的值不连续。

这种行为对我来说是不直观的，我希望分配给同一个键的所有数据点都分组在一起，但这是另一个讨论。

无论如何，我的问题是：如何使用 Thrust 对交错数组的列求和？

Answer 1

这些操作（求和行、求和列等）通常在 GPU 上受内存带宽限制。因此，我们可能要考虑如何构建一种算法，以最佳利用 GPU 内存带宽。特别是，如果可能的话，我们希望从推力代码生成的底层内存访问被合并。简而言之，这意味着相邻的 GPU 线程将从内存中的相邻位置读取。

原来的row-summing example显示这个属性：推力产生的相邻线程将读取内存中的相邻元素。例如，如果我们有 R 行，那么我们可以看到由 thrust 创建的第一个 R 线程将全部读取矩阵的第一个 "row"，在 reduce_by_key 手术。由于与第一行关联的内存位置都组合在一起，我们得到合并访问。

解决此问题（如何对列求和）的一种方法是使用与行求和示例类似的策略，但使用 permutation_iterator 来使所有线程都属于相同的键序列来读取列数据而不是行数据。这个置换迭代器将采用底层数组和一个映射序列。此映射序列由 transform_iterator 使用应用于 counting_iterator 的 special functor 创建，以将线性（行优先）索引转换为列优先索引，以便第一个 C 线程将读取矩阵的第一列的元素，而不是第一行。由于前 C 个线程将属于相同的键序列，因此它们将在 reduce_by_key 操作中加在一起。这就是我在下面的代码中所说的方法 1。

但是，这种方法的缺点是相邻线程不再读取内存中的相邻值 - 我们破坏了合并，正如我们将看到的，性能影响是显而易见的。

对于以行优先顺序存储在内存中的大型矩阵（我们在这个问题中一直在讨论的顺序），对列求和的一个相当最佳的方法是让每个thread 使用 for 循环对单个列求和。这在 CUDA C 中实现起来相当简单，我们可以使用适当定义的函子在 Thrust 中类似地执行此操作。

我在下面的代码中将其称为方法 2。此方法只会启动与矩阵中的列一样多的线程。对于列数足够多（例如 10,000 或更多）的矩阵，此方法将使 GPU 饱和并有效地使用可用内存带宽。如果您检查仿函数，您会发现它有点 "unusual" 对推力的改编，但完全合法。

这是比较两种方法的代码：

$ cat t994.cu
#include <thrust/device_vector.h>
#include <thrust/reduce.h>
#include <thrust/iterator/permutation_iterator.h>
#include <thrust/iterator/transform_iterator.h>
#include <thrust/iterator/counting_iterator.h>
#include <thrust/functional.h>
#include <thrust/sequence.h>
#include <thrust/transform.h>

#include <iostream>

#define NUMR 1000
#define NUMC 20000
#define TEST_VAL 1

#include <time.h>
#include <sys/time.h>
#define USECPSEC 1000000ULL

long long dtime_usec(unsigned long long start){

  timeval tv;
  gettimeofday(&tv, 0);
  return ((tv.tv_sec*USECPSEC)+tv.tv_usec)-start;
}


typedef int mytype;

// from a linear (row-major) index, return column-major index
struct rm2cm_idx_functor : public thrust::unary_function<int, int>
{
  int r;
  int c;

  rm2cm_idx_functor(int _r, int _c) : r(_r), c(_c) {};

  __host__ __device__
  int operator() (int idx)  {
    unsigned my_r = idx/c;
    unsigned my_c = idx%c;
    return (my_c * r) + my_r;
  }
};


// convert a linear index to a column index
template <typename T>
struct linear_index_to_col_index : public thrust::unary_function<T,T>
{
  T R; // number of rows

  __host__ __device__
  linear_index_to_col_index(T R) : R(R) {}

  __host__ __device__
  T operator()(T i)
  {
    return i / R;
  }
};

struct sum_functor
{
  int R;
  int C;
  mytype *arr;

  sum_functor(int _R, int _C, mytype *_arr) : R(_R), C(_C), arr(_arr) {};

  __host__ __device__
  mytype operator()(int myC){
    mytype sum = 0;
      for (int i = 0; i < R; i++) sum += arr[i*C+myC];
    return sum;
    }
};



int main(){
  int C = NUMC;
  int R = NUMR;
  thrust::device_vector<mytype> array(R*C, TEST_VAL);

// method 1: permutation iterator

// allocate storage for column sums and indices
  thrust::device_vector<mytype> col_sums(C);
  thrust::device_vector<int> col_indices(C);

// compute column sums by summing values with equal column indices
  unsigned long long m1t = dtime_usec(0);
  thrust::reduce_by_key(thrust::make_transform_iterator(thrust::counting_iterator<int>(0), linear_index_to_col_index<int>(R)),
   thrust::make_transform_iterator(thrust::counting_iterator<int>(R*C), linear_index_to_col_index<int>(R)),
   thrust::make_permutation_iterator(array.begin(), thrust::make_transform_iterator(thrust::make_counting_iterator<int>(0), rm2cm_idx_functor(R, C))),
   col_indices.begin(),
   col_sums.begin(),
   thrust::equal_to<int>(),
   thrust::plus<int>());
  cudaDeviceSynchronize();
  m1t = dtime_usec(m1t);
  for (int i = 0; i < C; i++)
    if (col_sums[i] != R*TEST_VAL) {std::cout << "method 1 mismatch at: " << i << " was: " << col_sums[i] << " should be: " << R*TEST_VAL << std::endl; return 1;}
  std::cout << "Method1 time: " << m1t/(float)USECPSEC << "s" << std::endl;

// method 2: column-summing functor

  thrust::device_vector<mytype> fcol_sums(C);
  thrust::sequence(fcol_sums.begin(), fcol_sums.end());  // start with column index
  unsigned long long m2t = dtime_usec(0);
  thrust::transform(fcol_sums.begin(), fcol_sums.end(), fcol_sums.begin(), sum_functor(R, C, thrust::raw_pointer_cast(array.data())));
  cudaDeviceSynchronize();
  m2t = dtime_usec(m2t);
  for (int i = 0; i < C; i++)
    if (fcol_sums[i] != R*TEST_VAL) {std::cout << "method 2 mismatch at: " << i << " was: " << fcol_sums[i] << " should be: " << R*TEST_VAL << std::endl; return 1;}
  std::cout << "Method2 time: " << m2t/(float)USECPSEC << "s" << std::endl;
  return 0;
}
$ nvcc -O3 -o t994 t994.cu
$ ./t994
Method1 time: 0.034817s
Method2 time: 0.00082s
$

很明显，对于足够大的矩阵，方法 2 比方法 1 快得多。

如果您不熟悉排列迭代器，请查看 thrust quick start guide。

CUDA/Thrust: 如何对交错数组的列求和？

CUDA/Thrust: How to sum the columns of an interleaved array?

c++

arrays

cuda

thrust