将扇区加载到内存时出现磁盘读取错误

Question

我尝试使用 this 开发引导加载程序，但是当它是运行时它显示：

disk read error!

如果我忽略它，在后面的部分，它会显示错误的内存映射。我也关注了其他一些来源，但都是徒劳的。感觉就像我只是在复制他们正在做的事情。如果我做一点不同，每次都会产生一种新的错误。

我应该使用已经构建的引导加载程序还是应该做什么？

磁盘加载错误代码如下：

[org 0x7c00]

    KERNEL_OFFSET equ 0x1000    
    mov [BOOT_DRIVE], dl        
    mov bp, 0x9000          
    mov sp, bp  
    mov bx, MSG_REAL_MODE       
    call print_string           
    call load_kernel            
    jmp $

print_string:
    pusha
    mov ah, 0x0e

loop:
    mov al,[bx]
    cmp al, 0
    je return
    int 0x10
    inc bx
    jmp loop

return:
    popa
    ret

disk_load: 
    push dx                                              
    mov ah, 0x02                                   
    mov al, dh                                          
    mov ch, 0x00                                    
    mov dh, 0x00                                     
    mov cl, 0x02                                    
    int 0x13                                           
    jc disk_error                                  
    pop dx                                               
    cmp dh, al                                         
    jne disk_error                                 
    ret

 disk_error :
   mov bx, DISK_ERROR_MSG 
   call print_string 
   jmp $

DISK_ERROR_MSG db "Disk read error!", 0

[bits 16]

load_kernel: 
    mov bx, KERNEL_OFFSET       
    mov dh, 15           
    mov dl, [BOOT_DRIVE]                      
    call disk_load                                                  
    ret

; Global variables
BOOT_DRIVE     db 0 
MSG_REAL_MODE db "Started in 16-bit Real Mode", 0 

; Bootsector padding 
times 510-($-$$) db 0 
dw 0xaa55

我将此命令用于 assemble 和运行我的引导加载程序：

nasm boot.asm -f bin -o boot.bin && qemu-system-i386 boot.bin

我卡在这一点上了。我的引导加载程序显示 disk read error。如果我此时忽略它，那么它会在执行我的 kernel.c 时产生问题。它似乎使用了错误的内存映射。

Answer 1

"He's making a list, he's checking it twice..."

您的引导加载程序以实地址模式启动，因此最好强制您的汇编程序使用 16 位代码。您可以通过在程序顶部编写 [bits 16] 在 NASM 中实现此目的。
当您的引导加载程序启动时，BIOS 会将其放置在线性地址 00007C00h。对于段和偏移量的组合，它可以通过多种方式实现这一点。
当你明确地写 [org 0x7C00] 时，你（有点）期望这个组合的段部分等于零。但这绝不是 BIOS 的义务！因此，由您手动设置段寄存器（DS、ES 和 SS）。
您在 print_string 例程中使用的 BIOS 电传打字机函数使用 BL 和 BH 作为参数。所以你不应该使用 BX 寄存器来处理你的文本。当然，有些 BIOS 不再使用这些 BL 和 BH 参数（不再），但会尝试为最大的受众开发程序。
当您使用 0x9000 初始化 SP 寄存器时，您有效地设置了一个堆栈，可以很容易地在您不注意的情况下覆盖它下面的程序！最好选择满足您需求的 SS 和 SP 组合，仅此而已。位于 7C00h 的引导扇区之上并在 9000h 结束的 4608 字节堆栈需要：SS=07E0h SP=1200h。为避免 8086 硬件出现任何问题，最好在更改 SS:SP 时禁用中断。
您使用了 pusha 和 popa 指令。这些不是 8086 硬件上的有效指令。在编写健壮的软件时，我们应该测试硬件是否能胜任这项任务。但这里最简单的解决方案是只 push/pop 单个寄存器。
您已经从从磁盘读取的 BIOS 函数中解释了 return 值，但您只是在传输的扇区数量不正确时中止。这是一种错误的做法。当 BIOS 告诉您传输不完整时（如果您的 BIOS 未启用多轨，则可能会发生这种情况），您必须对剩余的扇区数重复调用。显然必须调整一些参数：下一个磁头，也许是下一个柱面，并且总是扇区=1。（一个完美的解决方案是从 BIOS 检索磁盘几何结构或从磁盘上存在的 BPB 读取它）。我假定基本的 1.44 MB 软盘操作。
如果第一次从磁盘读取不成功，您应该重试多次。这样的第一次失败是完全正常的。五次重试是一个很好的价值。在两次尝试之间调用重置磁盘驱动器的 BIOS 函数。
为了确保 QEMU 可以实际读取那些额外的 15 个扇区，您应该填充此文件，使其总长度为 16 个扇区。您链接到的 text 也这样做了！

"Putting it all together"

[bits 16]
[org 0x7C00]

KERNEL_OFFSET equ 0x1000

xor  ax, ax
mov  ds, ax
mov  es, ax    
mov  [BOOT_DRIVE], dl
mov  ax, 0x07E0
cli
mov  ss, ax 
mov  sp, 0x1200
sti
mov  si, MSG_REAL_MODE       
call print_string           
call load_kernel            
jmp  $

print_string:
  push ax
  push bx
  push si
  mov  bx, 0x0007  ;BL=WhiteOnBlack BH=Display page 0
  mov  ah, 0x0E    ;Teletype function
 loop:
  mov  al, [si]
  cmp  al, 0
  je return
  int  0x10
  inc  si
  jmp  loop
 return:
  pop  si
  pop  bx
  pop  ax
  ret

disk_load:
  mov  [SECTORS], dh
  mov  ch, 0x00      ;C=0
  mov  dh, 0x00      ;H=0
  mov  cl, 0x02      ;S=2
 next_group:
  mov  di, 5         ;Max 5 tries
 again: 
  mov  ah, 0x02      ;Read sectors
  mov  al, [SECTORS]
  int  0x13
  jc   maybe_retry
  sub  [SECTORS], al ;Remaining sectors
  jz  ready
  mov  cl, 0x01      ;Always sector 1
  xor  dh, 1         ;Next head on diskette!
  jnz  next_group
  inc  ch            ;Next cylinder
  jmp  next_group
 maybe_retry:
  mov  ah, 0x00      ;Reset diskdrive
  int  0x13
  dec  di
  jnz  again
  jmp  disk_error
 ready:
  ret

disk_error:
  mov  si, DISK_ERROR_MSG 
  call print_string 
  jmp  $

DISK_ERROR_MSG db "Disk read error!", 0

load_kernel: 
  mov  bx, KERNEL_OFFSET       
  mov  dh, 15           
  mov  dl, [BOOT_DRIVE]                      
  call disk_load                                                  
  ret

; Global variables
BOOT_DRIVE     db 0
SECTORS        db 0
MSG_REAL_MODE  db "Started in 16-bit Real Mode", 0 

; Bootsector padding 
times 510-($-$$) db 0 
dw 0xAA55

; 15 sector padding
times 15*256 dw 0xDADA

将扇区加载到内存时出现磁盘读取错误

Disk Read Error while loading sectors into memory

assembly

kernel

qemu

bootloader

osdev