TChromium：GetSourceProc 和不兼容的类型：'regular procedure and method pointer'

Question

我需要从 TChromium 中加载的页面获取源 HTML，但我需要将源存储在另一个 class 的变量中。换句话说，回调函数需要在另一个 class 中，我不能这样做，因为这个异常：

E2009 不兼容类型：'regular procedure and method pointer'

这是我的代码。仅当 'StringVisitor' 函数在 'Form1' class 之外时才有效。

有什么想法吗？

unit simple1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, cefvcl, ceflib;

type
  TForm1 = class(TForm)
    Chromium1: TChromium;
    procedure FormCreate(Sender: TObject);
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
      httpStatusCode: Integer);
  public
  mySource : string;
  procedure StringVisitor(const str: ustring);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
  httpStatusCode: Integer);
begin
  Chromium1.Browser.MainFrame.GetSourceProc(StringVisitor);  // error on this line
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
chromium1.load('http://www.google.com');
end;

procedure TForm1.StringVisitor(const str: ustring);
begin
mySource := str;
end;

end.

Answer 1

好的，使用 Delphi 7 我能够重现问题。

深入研究问题后，我发现有两种获取加载页面源的不同方法：

1) procedure GetSourceProc(const proc: TCefStringVisitorProc); 如您所用。该解决方案的问题是在 Dlephi 2009 之前，它只接受一个独立的过程，当您有多个对象实例并希望将您保留在其中时，这会给您带来问题 HTML。

2) procedure GetSource(const visitor: ICefStringVisitor);

让我们先看看预期的界面

  ICefStringVisitor = interface(ICefBase)
    ['{63ED4D6C-2FC8-4537-964B-B84C008F6158}']
    procedure Visit(const str: ustring);
  end;

所以我开始研究它。深入研究 unit ceflib; 后，我发现 TCefStringVisitorOwn，这是解决问题的关键。

TCefStringVisitorOwn的界面很简单：

  TCefStringVisitorOwn = class(TCefBaseOwn, ICefStringVisitor)
  protected
    procedure Visit(const str: ustring); virtual;
  public
    constructor Create; virtual;
  end;

因此，有了这个，我创建了 TCefStringVisitorOwn 的后代：

unit SourceContainerU;

interface

uses
  ceflib;

type
  ISourceContainer = interface(ICefStringVisitor)
    function Source: ustring;
  end;

  TSourceContainer = class(TCefStringVisitorOwn, ISourceContainer)
  private
    FSource: ustring;
  protected
    procedure Visit(const str: ustring); override;
  public
    function Source: ustring;
  end;

implementation

{ TSourceContainer }

function TSourceContainer.Source: ustring;
begin
  Result := FSource;
end;

procedure TSourceContainer.Visit(const str: ustring);
begin
  FSource := str;
end;

end.

这里没有魔法。

唯一剩下的就是使用这个 class 创建一个演示项目。在我的示例中，我在运行时创建了 TChromium。该表单包含一个按钮和一个备忘录，然后是此代码：

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls,
  cefvcl, ceflib, SourceContainerU;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    Chromium1: TChromium;
    SourceContainer : ISourceContainer;
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.Chromium1LoadEnd(Sender: TObject;  const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
begin
  if Frame = nil then
    exit;

  SourceContainer := TSourceContainer.Create;
  Frame.GetSource(SourceContainer);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Chromium1 := TChromium.Create(self);
  Chromium1.Parent := self;
  Chromium1.OnLoadEnd := Chromium1LoadEnd;
  Chromium1.load('http://www.google.com');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Assigned(SourceContainer) then
    Memo1.Lines.Text := SourceContainer.Source;
end;

end.

此解决方案已在最新版本的 Chromium 上进行测试，我已在 Delphi 7、[=53= 中对其进行了测试] XE 和 Delphi XE6。我没有任何 Delphi 2007 安装，但我相信它也应该在 wotk 中工作。

TChromium：GetSourceProc 和不兼容的类型：'regular procedure and method pointer'

TChromium : GetSourceProc and Incompatible types: 'regular procedure and method pointer'

delphi

chromium-embedded

tchromium