如何获取任何类型集合变量的元素数量？

Question

据我所知，没有内置函数。在网上搜索我发现了这个 function 并且它对我有用，但我不想使用它，因为它是程序集，我不明白它在做什么。所以我写了这个同样有效的函数：

function Cardinality(const PSet: PByteArray;
  const SizeOfSet(*in bytes*): Integer): Integer;
const
  Masks: array[0..7] of Byte = (1, 2, 4, 8, 16, 32, 64, 128);
var
  I, J: Integer;
begin
  Result := 0;
  for I := 0 to SizeOfSet - 1 do
    for J := 0 to 7 do
      if (PSet^[I] and Masks[J]) > 0 then
        Inc(Result);
end;

现在，我想知道我是否可以依赖这个功能？或者可能在 set 数据类型背后有一个技巧，这就是为什么 delphi 没有内置方法的原因。

但是if我的功能是可靠的then我怎样才能改进它：

将常量传递给它
进行类型检查并确保将集合传递给函数
传递值而不是它的地址
去掉SizeOfSet参数

我想这样称呼它 Cardinality(AnySet) 而不是 Cardinality(@AnySet, SizeOf(TAnySet))。

顺便说一句，我需要在 XE 和 XE5 中编译它。

Answer 1

您可以使用泛型和 RTTI 来实现它。像这样：

uses
  SysUtils, TypInfo;

type
  ERuntimeTypeError = class(Exception);

  TSet<T> = class
  strict private
    class function TypeInfo: PTypeInfo; inline; static;
  public
    class function IsSet: Boolean; static;
    class function Cardinality(const Value: T): Integer; static;
  end;

const
  Masks: array[0..7] of Byte = (1, 2, 4, 8, 16, 32, 64, 128);

implementation

{ TSet<T> }

class function TSet<T>.TypeInfo: PTypeInfo;
begin
  Result := System.TypeInfo(T);
end;

class function TSet<T>.IsSet: Boolean;
begin
  Result := TypeInfo.Kind=tkSet;
end;

function GetCardinality(const PSet: PByteArray;
  const SizeOfSet(*in bytes*): Integer): Integer; inline;
var
  I, J: Integer;
begin
  Result := 0;
  for I := 0 to SizeOfSet - 1 do
    for J := 0 to 7 do
      if (PSet^[I] and Masks[J]) > 0 then
        Inc(Result);
end;

class function TSet<T>.Cardinality(const Value: T): Integer;
var
  EnumTypeData: PTypeData;
begin
  if not IsSet then
    raise ERuntimeTypeError.Create('Invalid type in TSet<T>, T must be a set');
  Result := GetCardinality(PByteArray(@Value), SizeOf(Value));
end;

用法：

Writeln(TSet<SomeSet>.Cardinality(Value));

Answer 2

在 Delphi 的早期版本中，您可以这样做：

function Card(ASet: TSet): Integer;
var
  k: TSetElement;
begin
  Result := 0;
  for k in ASet do Inc(Result);
end;

如何获取任何类型集合变量的元素数量？

How can I get the number of elements of any variable of type set?

delphi

set

delphi-xe

delphi-xe5