Mathematica 生成带锁定位的二进制数

Question

我有一个非常具体的 Mathematica 问题。我正在尝试围绕某些 'locked' 位生成所有二进制数。我正在使用字符串值列表来表示哪些位被锁定，例如{"U","U,"L","U"}，其中 U 是一个 "unlocked" 可变位，L 是一个 "locked" 不可变位。我从一个临时的开始已格式化为先前列表的随机二进制数列表，例如 {0, 1, 1, 0}，其中 1是锁定位，我需要找到1[的所有剩余二进制数=22=] 位是不变的。我已经递归地、迭代地解决了这个问题，并且两者结合都没有结果。这是我在大学里做的研究。

我正在构建一个以 10 为基数的二进制数列表。我意识到这段代码是完全错误的。这只是一次尝试。

Do[ If[bits[[pos]] == "U", AppendTo[returnList, myFunction[bits, temp, pos, returnList]]; ], {pos, 8, 1}] myFunction[bits_, bin_, pos_, rList_] := Module[{binary = bin, current = Length[bin], returnList = rList}, If[pos == current, Return[returnList], If[bits[[current]] == "U", (*If true*) If[! MemberQ[returnList, FromDigits[binary, 2]], (*If true*) AppendTo[returnList, FromDigits[binary, 2]]; binary[[current]] = Abs[binary[[current]] - 1], (*If false*) binary[[current]] = 0; current = current - 1]; , (*If false*) current = current - 1]; returnList = myFunction[bits, binary, pos, returnList]; Return[returnList]]]

Answer 1

myFunction[bits_] := Module[{length, num, range, all, pattern},
  length = Length[bits];
  num = 2^length;
  range = Range[0, num - 1]; 
  all = PadLeft[IntegerDigits[#, 2], length] & /@ range;
  pattern = bits /. {"U" -> _, "L" -> 1};
  Cases[all, pattern]]

bits = {"U", "U", "L", "U"};

myFunction[bits]

{{0, 0, 1, 0}, {0, 0, 1, 1}, {0, 1, 1, 0}, {0, 1, 1, 1},
 {1, 0, 1, 0}, {1, 0, 1, 1}, {1, 1, 1, 0}, {1, 1, 1, 1}}

Answer 2

您可以使用 Tuples 和 Fold 只生成您感兴趣的位集。

bits = {"U", "U", "L", "U"};

Fold[
  Function[{running, next}, 
    Insert[running, 1, next]], #, Position[bits, "L"]] & /@ Tuples[{0, 1}, Count["U"]@bits]

(*
{{0, 0, 1, 0}, {0, 0, 1, 1}, {0, 1, 1, 0}, {0, 1, 1, 1}, 
 {1, 0, 1, 0}, {1, 0, 1, 1}, {1, 1, 1, 0}, {1, 1, 1, 1}}
*)

希望对您有所帮助。

Answer 3

in = IntegerDigits[Round[ Pi 10^9 ], 2];
mask = RandomSample[ConstantArray["L", 28]~Join~ConstantArray["U", 4],32];

subs[in_, mask_] := Module[ {p = Position[mask, "U"]} ,
       ReplacePart[in, Rule @@@ Transpose[{p, #}]] & /@ 
          Tuples[{0, 1}, Length@p]]
subs[in, mask]

{{1, 0, 1, 1, 1, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 0, 0, 1, 0, 0, 1, 0, 1, 0}, {1, 0, 1, 1, 1, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 0, 1, 1, 0, 0, 0, 1, 1, 0, 0, 1, 0, 0, 1, 1, 1, 0}, {1, 0, 1, 1, 1, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0, 0, 1, 0, 0, 1, 0, 1, 0}, {1, 0, 1, 1, 1, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 0, 1, 1, 1, 0, 0, 1, 1, 0, 0, 1, 0, 0, 1, 1, 1, 0}, ...

 FromDigits[#, 2] & /@ %

{3108030026, 3108030030, 3108038218, 3108038222, 3108095562, 3108095566, 3108103754, 3108103758, 3141584458, 3141584462, 3141592650, 3141592654, 3141649994, 3141649998, 3141658186, 3141658190}

Mathematica 生成带锁定位的二进制数

Mathematica Generate Binary Numbers with Locked Bits

algorithm

binary

wolfram-mathematica