将日期转换为儒略日期的批处理脚本

Question

我正在创建一个批处理文件以将 %date% 转换为儒略日期，但我似乎找不到有关执行此操作的明确信息。谁能告诉我如何将 %date% 转换为儒略日期？或任何已经存在的批处理文件？

谢谢

Answer 1

this 这里有一个 julian.bat:

@if (@X)==(@Y) @end /* JScript comment
    @echo off

    cscript //E:JScript //nologo "%~f0" 

    exit /b %errorlevel%

@if (@X)==(@Y) @end JScript comment */


Date.prototype.getJulian = function() {
    return Math.floor((this / 86400000) - (this.getTimezoneOffset()/1440) + 2440587.5);
}

var today = new Date(); //set any date
var julian = today.getJulian(); //get Julian counterpart
WScript.Echo(julian);

它可以像这样使用：

for /f %%a in ('call julian.bat') do @set "julian=%%a"

Answer 2

编辑：原始代码修改为仅以"Dow MM/DD/YYYY"格式显示当前日期的儒略日数：

@echo off
for /F "tokens=2-4 delims=/ " %%a in ("%date%") do (
   set /A "a=(%%a-14)/12, JDN=(1461*(%%c+4800+a))/4+(367*(%%a-2-12*a))/12-(3*((%%c+4900+a)/100))/4+%%b-32075"
)
echo %JDN%

参考：http://www.hermetic.ch/cal_stud/jdn.htm#comp

第二。编辑

要根据一年中的天数（从 1 到 366）获取序日数，请使用此方法：

@echo off
setlocal

for /F "tokens=2-4 delims=/ " %%a in ("%date%") do (
   set /A "MM=1%%a-100, DD=1%%b-100, Ymod4=%%c%%4"
)
for /F "tokens=%MM%" %%m in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A Day=DD+%%m
if %Ymod4% equ 0 if %MM% gtr 2 set /A Day+=1

echo %Day%

Answer 3

@Aacini - 你的答案非常有效......除非月份或日期是 08 或 09 - 然后批处理会混淆并认为这是非法八进制的尝试。我看不出如何将它保持在一行上，但这里有一个解决方案（经过测试，并结合了@jeb 评论）：

:get_julian
    for /F "tokens=1-3 delims=/" %%a in ("%1") do (
        set /a mon=100%%a %% 100
        set /a day=100%%b %% 100
        set year=%%c
    )
    set /a x=(mon-14)/12
    set /a JD=(1461*(year+4800+x))/4+(367*(mon-2-12*x))/12-(3*((year+4900+x)/100))/4+day-32075
    exit /b

将日期转换为儒略日期的批处理脚本

batch script that converts date to julian date

batch-file

julian-date