optparse-applicative 子命令帮助文本

Question

我正在使用 stackage lts 5.1 附带的 optparse-applicative 我有一个带有子命令的解析器，我已经描述了它们的选项的帮助文本，但它们没有显示。

这是我运行带有 --help 的可执行文件时的输出：

[david@devcentos65 manipro]$ /home/david/.local/bin/manipro --help
manipro - text1

Usage: manipro COMMAND [-v|--verbose]   text2

Available options:  
  -h,--help                Show this help text  
  -v,--verbose             text3

Available commands:   
  export                   text4
  dico                     text9

代码：

parserArgs :: ParserInfo ArgApp
parserArgs = info (helper <*> args) desc
    where
    desc =  
        fullDesc <> 
        progDesc "text1"  <> 
        header "text2"


args = ArgApp <$> argCmd <*> optverbose
    where
    optverbose = switch ( 
        short 'v' <> long "verbose" <> 
        help "text3" )

argCmd = subparser (argCmdExport <> argCmdDico)

argCmdExport = command "export" infos
    where
    infos = info options desc
    desc  = progDesc "text4" 
    options = ArgCmdExport <$> 
        argModeExport <*> 
        argTableExport <*> 
        argOptExport

argModeExport  = argument auto (metavar "FORMAT")
argTableExport = argument text (metavar "TABLE")

argOptExport = ArgOptExport <$> optional noesc <*> optional cols <*>
    ens <*> tst
    where
    noesc = option textList (long "noesc" <> metavar "CHAMPS" <> help "text5" )
    cols = option textList (long "cols" <> metavar "CHAMPS" <> help "text6" )
    ens = flag EnsEtoile  EnsDollar (short 'd' <> long "dollar" <> 
        help "text7") 
    tst = flag False True (short 't' <> long "test" <> 
        help "text8")

argCmdDico    = command "dico" infos
    where
    infos = info options desc
    desc  = progDesc "text9" 
    options = ArgCmdDico <$> 
        argOptDico

argOptDico = ArgOptDico <$> optional tables
    where
    tables = option textList (long "tables" <> metavar "TABLES" <>
        help "text10" )


text = str >>= return . pack
textList = str >>= return . splitOn "," . pack

Answer 1

如果只使用--help，

optparse-applicative故意隐藏命令的详细描述。毕竟，您可能有十几个命令。例如，stack 有 34。列表可能会垂直填满您的终端。如果它显示所有可能的参数，您最终会得到很多文本。

相反，--help 将仅显示常用参数和命令列表。为了显示单个命令的描述，您必须使用 <executable> <command> --help:

$ stack --help | head
stack - The Haskell Tool Stack

Usage: stack [--help] [--version] [--numeric-version] [--docker*] [--nix*]
             ([--verbosity VERBOSITY] | [-v|--verbose]) [--work-dir WORK-DIR]
             [--[no-]system-ghc] [--[no-]install-ghc] [--arch ARCH] [--os OS]
             [--ghc-variant VARIANT] [-j|--jobs JOBS] [--extra-include-dirs DIR]
             [--extra-lib-dirs DIR] [--[no-]skip-ghc-check] [--[no-]skip-msys]
             [--local-bin-path DIR] [--[no-]modify-code-page]
             [--resolver RESOLVER] [--compiler COMPILER] [--[no-]terminal]
             [--stack-yaml STACK-YAML] COMMAND|FILE

$ stack --help | grep clean
  clean                    Clean the local packages

$ stack clean --help
Usage: stack clean [PACKAGE] [--help]
  Clean the local packages

Available options:
  PACKAGE                  If none specified, clean all local packages
  --help                   Show this help text

Run 'stack --help' for global options that apply to all subcommands.

这在一定程度上减少了混乱。它还遵循与其他流行的多命令应用程序相同的规则，例如 git 和 hg（除了 <executable> --help <command> 仍然只显示一般帮助的小例外）。

Answer 2

正如 Zeta 指出的那样，单个命令的描述显示在 <executable> <command> --help 上。但是为了让它工作，在 optparse-applicative 中，每个命令的子解析器都需要一个选项 --help 的解析器。您只为 <executable> --help 定义了一个（请参阅 haskell 代码块的第二行）。如果没有针对特定命令的帮助解析器，<executable> <command> --help 的输出将不是帮助消息，而是关于 invalid option --help 的通知和用法说明。

一般模式是按顺序将 --help 选项的解析器（即 helper）应用于命令参数的解析器，如下所示：command "command-name" (info (yourCommandArgParser <**> helper) (fullDesc <> progDesc "your commands description" <> ...)).

所以对于 export 命令你可以这样写：

argCmdExport = command "export" infos
    where
    infos = info (options <**> helper) desc
    desc  = progDesc "text4" 
    options = ArgCmdExport <$> 
        argModeExport <*> 
        argTableExport <*> 
        argOptExport

PS。这个问题很老，但是当我遇到同样的问题时，我偶然发现了它。而且网络上仍然没有任何相关信息。

optparse-applicative 子命令帮助文本

optparse-applicative subcommand help text

haskell

command-line-arguments

applicative

optparse-applicative