DUnitX 从字符串到整数数组的转换

Question

我的问题类似于，但我想传递一个整数数组而不是集合。

例如：

[TestCase('TestAdd','[1,2,3,4];[1,2,3,4]',';')]
procedure TestAdd(aValue, aResult: array of integer);

修改 DUnitX.Utils 似乎是最简洁的方法，但我不确定如何进行转换。我的主要问题是，它怎么知道我需要一个整数的数组？ PTypeInfo 中有什么我可以利用的吗？

Answer 1

您不能使用开放数组，因为 RTTI 缺少使用此类参数调用方法的代码（实际上由两个参数在后台实现）。因此，您需要更改签名以使用 TArray<T> 或任何其他动态数组类型。

那么对 DUnitX.Utils 的修改就非常简单了——只需将此函数添加到 tkUString->tkDynArray 的 Conversions 数组中（任何可能的优化留作 reader 的练习）：

function ConvStr2DynArray(const ASource: TValue; ATarget: PTypeInfo; out AResult: TValue): Boolean;
var
  s: string;
  values: TStringDynArray;
  i: Integer;
  p: Pointer;
  v1, v2: TValue;
  elType: PTypeInfo;
begin
  s := ASource.AsString;
  if StartsStr('[', s) and EndsStr(']', s) then
    s := Copy(s, 2, Length(s) - 2);
  values := SplitString(s, ',');
  i := Length(values);
  p := nil;
  DynArraySetLength(p, ATarget, 1, @i);
  TValue.MakeWithoutCopy(@p, ATarget, AResult);
  elType := ATarget.TypeData.DynArrElType^;
  for i := 0 to High(values) do
  begin
    v1 := TValue.FromString(values[i]);
    if not v1.TryConvert(elType, v2) then
      Exit(False);
    AResult.SetArrayElement(i, v2);
  end;
  Result := True;
end;

DUnitX 从字符串到整数数组的转换

DUnitX Conversion from string to array of integer

delphi

unit-testing

dunitx

delphi-10-seattle