使用 CMake 安装外部项目

Question

我的 CMakeLists.txt 之一中有以下代码：

FIND_PACKAGE(sphinxbase)
if (${SPHINXBASE_FOUND})
    INCLUDE_DIRECTORIES(${SPHINXBASE_INCLUDE_DIR}/sphinxbase/)
else ()
    ExternalProject_Add(
        sphinxbase
        GIT_REPOSITORY      "https://github.com/cmusphinx/sphinxbase.git"
        GIT_TAG             "e34b1c632392276101ed16e8a05862e43f038a7c"
        SOURCE_DIR          ${CMAKE_CURRENT_SOURCE_DIR}/lib/sphinxbase
        CONFIGURE_COMMAND   ${CMAKE_CURRENT_SOURCE_DIR}/lib/sphinxbase/autogen.sh
        BUILD_COMMAND       ${MAKE}
        UPDATE_COMMAND      ""
        INSTALL_COMMAND     ""
        BUILD_IN_SOURCE     ON
        LOG_DOWNLOAD        ON
        LOG_UPDATE          ON
        LOG_CONFIGURE       ON
        LOG_BUILD           ON
        LOG_TEST            ON
        LOG_INSTALL         ON
    )
    ExternalProject_Get_Property(sphinxbase SOURCE_DIR)
    ExternalProject_Get_Property(sphinxbase BINARY_DIR)
    SET(SPHINXBASE_SOURCE_DIR ${SOURCE_DIR})
    SET(SPHINXBASE_BINARY_DIR ${BINARY_DIR})
    SET(SPHINXBASE_LIBRARIES ${SPHINXBASE_BINARY_DIR}/src/libsphinxbase/.libs/libsphinxbase.a)
    INCLUDE_DIRECTORIES(${SPHINXBASE_SOURCE_DIR}/include)
endif ()
SET(DEPENDENCIES ${DEPENDENCIES} sphinxbase)
SET(LIBS ${LIBS} ${SPHINXBASE_LIBRARIES})

除了我尝试安装的 TARGET 之外，我将如何安装这个 ExternalProject？现在我正在尝试这样做：

install(TARGETS ${LIBS}
        LIBRARY DESTINATION lib
        ARCHIVE DESTINATION lib
        OPTIONAL
        )

install(TARGETS ${PROJECT_NAME}
        RUNTIME DESTINATION bin
        )

但是我收到以下错误：

CMake Error at CMakeLists.txt:197 (install):
  install TARGETS given target
  "/Users/syb0rg/Dropbox/Development/Khronos/Khronos/lib/sphinxbase/src/libsphinxbase/.libs/libsphinxbase.a"
  which does not exist in this directory.

有什么建议吗？

Answer 1

命令流 install(TARGETS) 安装目标，它们是使用 add_executable 或 add_library 命令创建的。要安装具体文件，您需要使用命令流 install(FILES).

不是从子项目的 build 目录安装选定的文件，您可以按原样 安装子项目 。为此，您可以使用

make DESTDIR=<...> install

命令作为 ExeternalProject_Add 的 INSTALL 选项。此命令会将 整个子项目 安装到作为 make 的 DESTDIR 参数给出的目录中（有关此参数的更多信息，请参见 here）。

然后你可以使用install(DIRECTORY)命令一次安装所有子项目的文件：

# It is better to use binary directory for download or build 3d-party project 
set(sphinxbase_SOURCE_DIR ${CMAKE_CURRENT_BINARY_DIR}/lib/sphinxbase)
# This will be used as DESTDIR on subproject's `make install`.
set(sphinxbase_DESTDIR ${CMAKE_CURRENT_BINARY_DIR}/lib/sphinxbase_install)

ExternalProject_Add(
    sphinxbase
    GIT_REPOSITORY      "https://github.com/cmusphinx/sphinxbase.git"
    GIT_TAG             "e34b1c632392276101ed16e8a05862e43f038a7c"
    SOURCE_DIR          ${sphinxbase_SOURCE_DIR}
    # Specify installation prefix for configure.sh (autogen.sh).
    CONFIGURE_COMMAND   ./autogen.sh --prefix=${CMAKE_INSTALL_PREFIX}
    BUILD_COMMAND       ${MAKE}
    UPDATE_COMMAND      ""
    # Fake installation: copy installed files into DESTDIR.
    INSTALL_COMMAND     make DESTDIR=${sphinxbase_DESTDIR} install
    ...
)
# Actually install subproject.
install(DIRECTORY ${sphinxbase_DESTDIR}/ DESTINATION "/")

注意，根目录用作DESTINATION。这是因为 sphinxbase_DESTDIR 目录下的文件已经根据 CMAKE_INSTALL_PREFIX 定位，它作为 --prefix 选项传递给 configure.sh（在给定的情况下为 autogen.sh）。

如果你知道，子项目只在安装前缀下安装它的文件（由 --prefix 给出），你可以使主项目安装更 packaging-friendly:

install(DIRECTORY ${sphinxbase_DESTDIR}/${CMAKE_INSTALL_PREFIX}/ DESTINATION ".")

因为相对路径用于DESTINATION选项，项目将正确支持打包。例如，make DESTDIR=<...> install 也适用于主项目。

请注意，即使 ExternalProject_Add 用于构建 CMake 子项目，主项目也看不到在此子项目中创建的目标。

使用 CMake 安装外部项目

Installing an ExternalProject with CMake

installation

build-process

build

cmake

external-project