从 Outlook 中的特定文件夹下载附件

Question

我对 vba 不够熟悉，无法根据需要修改它。

我需要从特定文件夹下载附件。

我找到了这个 example，但我不确定如何获取这些电子邮件发送到的文件夹。

我有一个规则，当收到这些电子邮件时，会将它们放入不同的文件夹中。

这是我想要运行宏的地方，因此它只会从这些电子邮件中删除附件并将它们放在本地计算机文件夹中。

我需要更改哪些部分才能使其满足我的需要？

Public Sub SaveAttachments(Item As Outlook.MailItem)

If Item.Attachments.Count > 0 Then

Dim objAttachments As Outlook.Attachments
Dim lngCount As Long
Dim strFile As String
Dim sFileType As String
Dim i As Long

Set objAttachments = Item.Attachments
    lngCount = objAttachments.Count
 For i = lngCount To 1 Step -1

' Get the file name.
 strFile = objAttachments.Item(i).FileName

 ' Get the path to your My Documents folder
    strfolderpath = CreateObject("WScript.Shell").SpecialFolders(16)
    strfolderpath = strfolderpath & "\Attachments\"

' Combine with the path to the folder.
 strFile = strfolderpath & strFile

' Save the attachment as a file.
 objAttachments.Item(i).SaveAsFile strFile

 Next i
End If

End Sub

Answer 1

要打开与收件箱同级的文件夹，请打开收件箱，然后向上一级到其父级，然后按名称检索您的文件夹：

set MyFolder = Application.Session.GetDefaultFolder(olFolderInbox).Parent.Folders.Item("My Folder Name")

Answer 2

代码在ThisOutlookSession下更新文件夹名称"Temp"

Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
    Dim olNameSpace As Outlook.NameSpace
    Dim olFolder  As Outlook.MAPIFolder

    Set olNameSpace = Application.GetNamespace("MAPI")
    Set olFolder = olNameSpace.GetDefaultFolder(olFolderInbox).Folders("TEMP")
    Set Items = olFolder.Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
    If TypeOf Item Is Outlook.MailItem Then
        SaveAttachments Item
    End If
End Sub

'// http://www.slipstick.com/developer/save-attachments-to-the-hard-drive/
Public Sub SaveAttachments(Item As Outlook.MailItem)

    If Item.Attachments.Count > 0 Then

        Dim objAttachments As Outlook.Attachments
        Dim lngCount As Long
        Dim strFile As String
        Dim sFileType As String
        Dim i As Long

        Set objAttachments = Item.Attachments
            lngCount = objAttachments.Count
        For i = lngCount To 1 Step -1

            ' Get the file name.
            strFile = objAttachments.Item(i).FileName

            ' Get the path to your My Documents folder
            strFolderpath = CreateObject("WScript.Shell").SpecialFolders(16)
            strFolderpath = strFolderpath & "\Attachments\"

            ' Combine with the path to the folder.
            strFile = strFolderpath & strFile

            ' Save the attachment as a file.
            objAttachments.Item(i).SaveAsFile strFile

        Next i
    End If

End Sub

从 Outlook 中的特定文件夹下载附件

Download attachments from specific folder in Outlook

vba

outlook

outlook-2010