从 Windows 10 使用 Visual Studio 2008 调试 Windows CE 设备

Question

我这周从 Windows 7 升级到 Windows 10。我为移动设备开发紧凑的框架软件（Windows CE7，Windows 移动设备，例如）。我使用 Visual Studio 2008.

现在我收到错误："error connecting to device"（设备连接组件）。

Windows 移动设备中心运行并且该设备显示在我的资源管理器中。有什么提示吗？

Answer 1

我解决了我的问题：

在 Visual Studio 2008 中，您可以在 "Windows Mobile 5.0 Pocket PC Device" 和 "Windows Mobile 5.0 Pocket PC Device R2"

之间进行选择

我不得不选择 "R2" 然后它对我有用。

Answer 2

为了帮助其他人，我在 Windows 10 上使用 Visual Studio 2008 并尝试连接到 Windows CE 5.0 设备，遇到同样的问题。

设备正在被 Win 10 检测到，我可以从我的 PC 等浏览它的文件系统，但是 VS2008 无法连接并显示消息：

ActiveSync bootstrap initialization failed. Please connect/cradle a real device or download the User-level Windows Mobile Device Center Application from...

最后我通过手动安装 Windows Mobile Device Center 6.1 (there's also a 32 bit version)

让它工作了

Answer 3

我不记得我从哪里得到这个 WMDC_Service_Fix.bat 文件，但它在 Windows 10 中为我修复了与设备的连接。

这是批处理文件的内容，只需重新创建它并运行它：

@echo off
::WcesComm is the name of the "Windows Mobile-2003-based device connectivity" service.
::RapiMgr is the name of the "Windows Mobile-based device connectivity" service.
::Both being necessary for proper WMDC functionality.

::The following registry entires set the RapiMgr and WcesComm services to run as seperate processes
REG ADD HKLM\SYSTEM\CurrentControlSet\Services\RapiMgr /v SvcHostSplitDisable /t REG_DWORD /d 1 /f > nul 2>&1
REG ADD HKLM\SYSTEM\CurrentControlSet\Services\WcesComm /v SvcHostSplitDisable /t REG_DWORD /d 1 /f > nul 2>&1
if %errorLevel% == 0 (
    echo Service Registry entries added successfully
    ) else (
        echo Failure: Please run this file as admin.
    goto end_Pause
    )
::Set the compatability of wmdc.exe to Windows Vista (which works more consistently)
REG ADD "HKLM\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers" /v "C:\Windows\WindowsMobile\wmdc.exe" /d "~ VISTARTM" /f > nul 2>&1
if %errorLevel% == 0 (
    echo Compatability Mode for WMDC successfully set
    ) else (
        echo Failure: Please manually set the compatibility mode for
    echo C:\Windows\WindowsMobile\wmdc.exe
    echo to "Vista" for all users.
    )
echo.

::Stop both the services associated with WMDC
net stop WcesComm
net stop RapiMgr

::Set both the services to run as LocalSystem
sc config WcesComm obj= LocalSystem password= "" > nul 2>&1
sc config RapiMgr obj= LocalSystem password= "" > nul 2>&1
if %errorLevel% == 0 (
    echo Services configured to Log in As LocalSystem
    ) else (
        echo Failure: Services could not be updated
    )

echo.

::Restart the services. Starting WCesComm also starts RapiMgr
net start WcesComm

:end_Pause
pause

我在设备上调试时使用 Windows CE Device 选项（带 Windows CE 6.0 的 Zebra MC2100）：

我还使用一个名为 Remote Display Control for Windows CE 或 CERDisp 的便捷小工具。在这里获取 https://forums.ivanti.com/s/article/CERDisp-Display-and-control-your-Windows-CE-device-from-your-desktop

从 Windows 10 使用 Visual Studio 2008 调试 Windows CE 设备

Debugging Windows CE Device from Windows 10 with Visual Studio 2008

visual-studio-2008

compact-framework

windows-10

mobile-devices