将 HTML colspan 和 rowspan 转换为 "empty" 单元格

Question

对于某种输出格式（不是 HTML-like），我需要将HTML tables转换为'square' tables，其中每个 colspan 和 rowspan 不仅在父单元格中指示，而且后面还有正确数量的空单元格。

例如，简单的HTMLtable

<table>
    <tr>
        <th>test</th>
        <th colspan="2">span 1/2</th>
        <th colspan="3">span 2/2</th>
    </tr>
    <tr>
        <td>col 1</td>
        <td>col 2</td>
        <td>col 3</td>
        <td>col 4</td>
        <td>col 5</td>
        <td>col 6</td>
    </tr>
</table>

应该翻译成

<table>
    <tr>
        <th>test</th>
        <th colspan="2">span 1/2</th>
        <th />  <!-- < empty cell added -->
        <th colspan="3">span 2/2</th>
        <th />  <!-- < empty cell added -->
    </tr>
    ..

（注意：输出格式使用非常不同的语法，这只是为了清楚起见！）

并且，类似地，rowspans 应该传播到下一个 <tr> 行：

<table><tr><td rowspan="3" /><td rowspan="2" /><td /></tr>
    <tr><td>data</td></tr>
    <tr><td>data</td><td>data</td></tr>
</table>

结果应该是

<table>
    <tr><td /><td /><td /></tr>
    <tr><td /><td /><td>data</td></tr>  <!-- 2 empty cells added -->
    <tr><td /><td>data</td><td>data</td></tr>  <!-- 1 empty cell added -->
<table>

处理 colspan 很简单：

<xsl:template name="add-empty">
    <xsl:param name="repeat" />

    <xsl:if test="$repeat &gt; 1">
        <td class="empty" />
        <xsl:call-template name="add-empty">
            <xsl:with-param name="repeat" select="$repeat - 1" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template match="th|td">
    <td>
        <xsl:apply-templates />
    </td>
    <xsl:if test="@colspan">
        <xsl:call-template name="add-empty">
            <xsl:with-param name="repeat" select="@colspan" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

这将添加单个 th 或 td，检查每个 colspan，并通过递归调用模板 add-empty 插入所需数量的空单元格. class 属性 empty 仅用于调试。

问题出在 rowspan 秒。为了使其正常工作，它需要扫描每个之前的 tr 并记录哪些列需要为空。该迭代类似于

<xsl:if test="position() &gt; 1">
    <xsl:variable name="currentRow" select="position()" />
    <xsl:for-each select="../tr[position() &lt; $currentRow]">
        <xsl:message>testing <xsl:value-of select="." /></xsl:message>
    </xsl:for-each>
</xsl:if>

– 不需要在第一行调用它，因为为此只需要添加 colspan。那么，这个问题有两个方面：我如何构建单元格集列表以添加到 current 行的正确集？有了这样一个列表，我如何遍历这个列表（只要table中的总列数）和每行的th|td元素？

后者是个问题，因为我可以使用类似

的方法遍历任一单元格集

<xsl:for-each select="1 to string-length(cell-set)">
  <xsl:if test="substring($cell-set, ., 1) = 'E'>
    .. empty ..
    ...
</xsl:for-each>

（如果 cell-set 是一个字符串），或在 'current' tr 内容上使用

<xsl:for-each select="th|td">
  ..

在这种情况下与cell-set的内容没有直接关系。第一个，我不知道插入td|th的哪个索引，第二个我不知道什么时候插入一个空白。

Answer 1

基于我已经在 link 中提到的 http://andrewjwelch.com/code/xslt/table/table-normalization.html，您可以使用：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0" exclude-result-prefixes="xs">

    <xsl:output indent="yes" omit-xml-declaration="yes" />

    <xsl:variable name="table_with_no_colspans">
        <xsl:apply-templates mode="colspan" />
    </xsl:variable>

    <xsl:variable name="table_with_no_rowspans">
        <xsl:for-each select="$table_with_no_colspans">
            <xsl:apply-templates mode="rowspan" />
        </xsl:for-each>
    </xsl:variable>

    <xsl:template match="/">
        <xsl:apply-templates select="$table_with_no_rowspans" mode="final" />
    </xsl:template>

    <xsl:template match="@*|*" mode="#all">
        <xsl:copy>
            <xsl:apply-templates select="@*|*" mode="#current" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="td | th" mode="colspan">
        <xsl:choose>
            <xsl:when test="@colspan">
                <xsl:copy>
                    <xsl:copy-of select="@* except @colspan"/>
                    <xsl:apply-templates/>
                </xsl:copy>
                <xsl:for-each select="2 to @colspan">
                    <td/>
                </xsl:for-each>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <!-- make sure it works for both table/tr and table/tbody/tr -->
    <xsl:template match="tbody|table[not(tbody)]" mode="rowspan">
        <xsl:copy>
            <xsl:copy-of select="tr[1]" />
            <xsl:apply-templates select="tr[2]" mode="rowspan">
                <xsl:with-param name="previousRow" select="tr[1]" />
            </xsl:apply-templates>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="tr" mode="rowspan">
        <xsl:param name="previousRow" as="element()" />

        <xsl:variable name="currentRow" select="." />

        <xsl:variable name="normalizedTDs">
            <xsl:for-each select="$previousRow/*">
                <xsl:choose>
                    <xsl:when test="@rowspan &gt; 1">
                        <xsl:copy>
                            <xsl:attribute name="rowspan">
                                <xsl:value-of select="@rowspan - 1" />
                            </xsl:attribute><!--
                            <xsl:copy-of select="@*[not(name() = 'rowspan')]" />
                            <xsl:copy-of select="node()" />
                        --></xsl:copy>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:copy-of select="$currentRow/*[1 + count(current()/preceding-sibling::*[not(@rowspan) or (@rowspan = 1)])]" />
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:variable>

        <xsl:variable name="newRow" as="element(tr)">
            <xsl:copy>
                <xsl:copy-of select="$currentRow/@*" />
                <xsl:copy-of select="$normalizedTDs" />
            </xsl:copy>
        </xsl:variable>

        <xsl:copy-of select="$newRow" />

        <xsl:apply-templates select="following-sibling::tr[1]" mode="rowspan">
            <xsl:with-param name="previousRow" select="$newRow" />
        </xsl:apply-templates>
    </xsl:template>

    <xsl:template match="td | th" mode="final">
        <xsl:choose>
            <xsl:when test="@rowspan">
                <xsl:copy>
                    <xsl:copy-of select="@* except @rowspan" />
                    <xsl:copy-of select="node()" />
                </xsl:copy>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

将 HTML colspan 和 rowspan 转换为 "empty" 单元格

Convert HTML colspan and rowspan to "empty" cells

xml

xslt

xslt-2.0