Perl6：是否有仅当您跳出循环时才运行的移相器？

Question

拿这个示例代码：

#!/usr/bin/env perl6

use v6.c;

ROLL:
for 1..10 -> $r {
    given (1..6).roll {
        when 6 {
            say "Roll $r: you win!";
            last ROLL;
        }
        default {
            say "Roll $r: sorry...";
        }
    }
    LAST {
        say "You either won or lost - this runs either way";
    }
}

我希望能够区分跳出循环和明确地说 last。理想情况下，会有一个移相器，但据我所知，在任何一种情况下都只有 LAST 运行。

有没有优雅的方法来做到这一点？（优雅，因此无需添加 $won 变量。）

Answer 1

我们正在处理 Perl，所以 有不止一种方法可以做到这一点；其中之一是使用主题变量 $_ 来保留值，以便我们可以轻松地重复匹配它：

constant N = 5;
for flat (1..6).roll xx * Z 1..N -> $_, $n {
    print "roll $n: $_ ";

    when 6 {
        put "(won)";
        last;
    }

    default {
        put "(lost)";
    }

    LAST {
        print "result: ";
        when 6 { put "winner :)" }
        default { put "loser :(" }
    }
}

Answer 2

这是另一种方法。优雅的？我认为是有道理的。不过，我希望有一个单独的移相器。

#!/usr/bin/env perl6

use v6.c;

constant MAX_ROLLS = 10;

ROLL:
for 1..MAX_ROLLS+1 -> $r {
    last ROLL if $r > MAX_ROLLS;

    given (1..6).roll {
        when 6 {
            say "Roll $r: you win!";
            last ROLL;
        }
        default {
            say "Roll $r: sorry...";
        }
    }

    LAST {
        say "You lost, better luck next time!" if $r > MAX_ROLLS;
    }
}

Perl6：是否有仅当您跳出循环时才运行的移相器？

Perl6: is there a phaser that runs only when you fall out of a loop?

raku