查找图中节点之间的路径及其长度

Question

我正在尝试解决这个问题，我已经阅读了 this 答案，但我的问题是无限循环，即使我使用了已访问的节点列表。

让我们看看我的两次尝试：

edge(1,2).
edge(1,4).
edge(1,3).
edge(2,3).
edge(2,5).
edge(3,4).
edge(3,5).
edge(4,5).


% ------ simple path finding in a directed graph

% -----  simple exploration

path0(A,B, Result) :-
    path0(A, B, [], Result).

path0(A, B, _, [e(A,B)]):- 
    edge(A,B).    
path0(A, B, Visited, [e(A,X)|Path]):-
    edge(A, X), dif(X, B),
    \+ member(X, Visited),
    path0(X, B, [A|Visited], Path ).    


%---- 1. exploration and length    

path(A, B, _, [e(A,B)], 1):- 
    edge(A,B).    
path(A, B, Visited, [e(A,X)|Path], Length):-
    edge(A, X),
    \+ member(X, Visited),
    length(Path, L),        % ERR: Path refers to a open list
    Length is L + 1,
    path(X, B, [A|Visited], Path, _).

% --- 2. not working

path2(A,B, Result, Length) :-
    path2(A, B, [], Result, Length).

path2(A, B, [], [e(A,B)], 1):- 
    edge(A,B).    
path2(A, B, Visited, [e(A,X)|Path], Length):-
    edge(A, X), dif(X, B),
    \+ member(X, Visited),
    path2(X, B, [A|Visited], Path, Len),
    Length is Len + 1.

这给了我类似的答案，即：

 ?- path(1,3, Path, Length).
Path = [e(1, 3)],
Length = 1 ;
Path = [e(1, 2), e(2, 3)],
Length = 2 ;

然后 Swi-Prolog IDE 冻结。

我应该将什么定义为基本情况？
~~为什么第二个实现是循环的，如果是这样，即使我使用了访问节点列表和dif()来确保避免统一来回？~~ 我打错了函数名。

我想摆脱 length/2 的使用。谢谢。

编辑：

所以，我发现这应该是更简洁的方法，即使我想要更类似于第二个实现的东西，它更容易在最短路径问题求解器中转换，因为它只是第一次调用 path3/4.

的 min{ pathLengths }

% ---- 3. working    
%   
min(A,B,A):- A =< B, !.       % for future use (shortest path)
min(_,B,B).

path3(From, To, Path, Len):-    
    path0(From, To, [], Path),
    length(Path, Len).
    %min(Len, MinLength, ?)

这是第二个实现路径2的更正版本：

% --- 2. 
% errors: 1. in base case I have to return Visited trough _, 
%             I can't pass a void list []
%         2. dif(X,B) is unuseful since base case it's the first clause

path2(A,B, Result, Length) :-
    path2(A, B, [], Result, Length).

path2(A, B, _, [e(A,B)], 1):-      % If an edge is found
    edge(A,B).    
path2(A, B, Visited, [e(A,X)|Path], Length):-
    edge(A, X),  
    %tab(1),write(A),write('-'),write(X),
    \+ member(X, Visited),
    %tab(1),write([A|Visited]),write(' visited'),nl,
    path2(X, B, [A|Visited], Path, Len),
    Length is Len + 1.

Answer 1

path/4 和 path2/4 都暴露出相似的非终止行为的原因是因为它们都使用了完全相同的辅助谓词 path/5。您可能指的是 path2/5：

path2(A,B, Result, Length) :-
    path(A, B, [], Result, Length).
 %  ^^^^ replace by path2

也许首先，让我们看看为什么您的 path/4 定义循环。为了看到这一点，我将在您的程序中插入目标 false。这些目标将减少推理的数量。当剩余的片段仍然循环时，我们可以确定我们看到了负责未终止的部分。经过一些实验，我发现了以下片段，称为 failure-slice:

edge(1,2).
edge(1,4) :- false.
edge(1,3) :- false.
edge(2,3) :- false.
edge(2,5) :- false.
edge(3,4) :- false.
edge(3,5) :- false.
edge(4,5) :- false.

path(A,B, Result, Length) :-
    path(A, B, [], Result, Length), false.

path(A, B, _, [e(A,B)], 1):- false,
    edge(A,B).
path(A, B, Visited, [e(A,X)|Path], Length):-
    edge(A, X),
    \+ member(X, Visited),
    length(Path, L), false,
    Length is L + 1,
    path(X, B, [A|Visited], Path, _).

所以本质上是使用 length/2 谓词。只要路径的长度不固定，这个片段就不会终止。所以对于查询

?- path(1, 3, Path, N).

Path 的长度不受限制，因此 length/2 会找到无限多的解 - 因此不会终止。

但是，毕竟，你为什么要知道长度呢？路径参数已经隐含地描述了它。

为你定义path/4,5考虑一下查询

?- path(1, X, Path, N).

应该产生一个答案。 Path = [1] 也应该是一个解决方案吗？ path/walk的确切定义有点问题。我觉得应该。

通用解决方案，请参考this answer。有了它，您可以像这样定义您感兴趣的谓词：

yourpath(A,B, Path, N) :-
   path(edge, Path, A,B),
   length(Path, N).

但是，我不想添加关于路径长度的额外参数。您以后可以随时添加该信息。

查找图中节点之间的路径及其长度

Find path and its length between nodes in a graph

prolog

graph-theory

shortest-path

failure-slice

non-termination