Unity3D Sprite ...但单面？

Question

Unity 的优秀 Sprites (Unity's excellent new sprites)，以及其他有价值的优势，实际上是双面的。

在 2D 或 3D 用例中，您可以将这些小混蛋翻转过来，仍然可以从后面看到它们 - 它们是从两侧渲染的。

我也喜欢用在它们上的无光照着色器（即 Sprite-Default，而不是 Sprite-Diffuse）。

但是，我需要一个老式的单面Sprite。

好在Unity使用的优秀shader的源码可以免费下载...迷惑的是不能直接在Editor中打开，而是看here and thence here.

经过 涉及廉价威士忌的大量持续努力，我对着色器进行了两 (2) 次修改。

我将文件第一行中的名称更改为“DefaultSingle”而不是“Default”
我注释掉了行 Cull Off

（然后我制作了一个新的 Material，将其命名为“Sprite Single Sided”，将着色器设置为这个新的，然后在 Sprites 上我替换了 material 插槽用那个新的 material.)

事实上，我是否通过进行此修改搞砸了着色器中的任何内容？是否可以在不引起进一步问题的情况下愉快地注释掉“剔除”？改变 Sprite 常用的 material 有什么问题吗（你不能“看到”它，所以我不知道）。更广泛地说，有没有更正确的方法来实现单面Sprite？

// file "Sprites-DefaultSingle.shader"
Shader "Sprites/DefaultSingle"
{
  Properties
  {
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)
    [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
  }

  SubShader
  {
    Tags
    { 
      "Queue"="Transparent" 
      "IgnoreProjector"="True" 
      "RenderType"="Transparent" 
      "PreviewType"="Plane"
      "CanUseSpriteAtlas"="True"
    }

  ///  Cull Off
    Lighting Off
    ZWrite Off
    Blend One OneMinusSrcAlpha

    Pass
    {
    CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag
      #pragma multi_compile _ PIXELSNAP_ON
      #pragma shader_feature ETC1_EXTERNAL_ALPHA
      #include "UnityCG.cginc"
      
      struct appdata_t
      {
        float4 vertex   : POSITION;
        float4 color    : COLOR;
        float2 texcoord : TEXCOORD0;
      };

      struct v2f
      {
        float4 vertex   : SV_POSITION;
        fixed4 color    : COLOR;
        float2 texcoord  : TEXCOORD0;
      };
      
      fixed4 _Color;

      v2f vert(appdata_t IN)
      {
        v2f OUT;
        OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
        OUT.texcoord = IN.texcoord;
        OUT.color = IN.color * _Color;
        #ifdef PIXELSNAP_ON
        OUT.vertex = UnityPixelSnap (OUT.vertex);
        #endif

        return OUT;
      }

      sampler2D _MainTex;
      sampler2D _AlphaTex;

      fixed4 SampleSpriteTexture (float2 uv)
      {
        fixed4 color = tex2D (_MainTex, uv);

#if ETC1_EXTERNAL_ALPHA
        // get the color from an external texture ..
        color.a = tex2D (_AlphaTex, uv).r;
#endif //ETC1_EXTERNAL_ALPHA

        return color;
      }

      fixed4 frag(v2f IN) : SV_Target
      {
        fixed4 c = SampleSpriteTexture (IN.texcoord) * IN.color;
        c.rgb *= c.a;
        return c;
      }
    ENDCG
    }
  }
}

Answer 1

据我所知，除了您想要的效果之外，这些更改都没有任何效果。此外，这是实现此目的的最正确方法 - 这是 Cull 的唯一用途。

Answer 2

这不会造成任何问题，是正确的做法。如果你想真正明确地说明它，你可以将该行更改为 Cull Back 而不是将其注释掉，但背面剔除被定义为默认行为，因此只需删除它就可以了。

Unity3D Sprite ...但单面？

Unity3D Sprite ... but single sided?

shader

unity3d

unity3d-2dtools