Unity 中 Google Cardboard 的 VR GUI

Question

我正在统一创建简单的 google 纸板游戏，我想添加分数计数。我知道如何正常进行，但在 VR 中它对我不起作用。我尝试只在其中放置文本和显示分数，它看起来不错（不完全是因为它只为一只眼睛显示）但是在我的 phone 上测试它之后，文本位于完全不同的位置。你知道正确的做法是什么吗？

Answer 1

创建一个世界 Space canvas 并将其 canvas 连接到相机。这就是我在 VR 游戏中获得 UI 的方式。

您需要为您的世界 Space UI 对象自定义着色器，该着色器具有要覆盖的渲染顺序并关闭 ZTest。

这是默认 UI 着色器的副本，并进行了必要的更改。应该做的伎俩。只需使用此着色器制作一个 material，然后将其应用到您想要在世界中的几何体顶部绘制的所有内容Space UI.

 Shader "UI/Default_OverlayNoZTest"
 {
     Properties
     {
         [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
         _Color ("Tint", Color) = (1,1,1,1)

         _StencilComp ("Stencil Comparison", Float) = 8
         _Stencil ("Stencil ID", Float) = 0
         _StencilOp ("Stencil Operation", Float) = 0
         _StencilWriteMask ("Stencil Write Mask", Float) = 255
         _StencilReadMask ("Stencil Read Mask", Float) = 255

         _ColorMask ("Color Mask", Float) = 15
     }

     SubShader
     {
         Tags
         { 
             "Queue"="Overlay" 
             "IgnoreProjector"="True" 
             "RenderType"="Transparent" 
             "PreviewType"="Plane"
             "CanUseSpriteAtlas"="True"
         }

         Stencil
         {
             Ref [_Stencil]
             Comp [_StencilComp]
             Pass [_StencilOp] 
             ReadMask [_StencilReadMask]
             WriteMask [_StencilWriteMask]
         }

         Cull Off
         Lighting Off
         ZWrite Off
         ZTest Off
         Blend SrcAlpha OneMinusSrcAlpha
         ColorMask [_ColorMask]

         Pass
         {
         CGPROGRAM
             #pragma vertex vert
             #pragma fragment frag
             #include "UnityCG.cginc"

             struct appdata_t
             {
                 float4 vertex   : POSITION;
                 float4 color    : COLOR;
                 float2 texcoord : TEXCOORD0;
             };

             struct v2f
             {
                 float4 vertex   : SV_POSITION;
                 fixed4 color    : COLOR;
                 half2 texcoord  : TEXCOORD0;
             };

             fixed4 _Color;

             v2f vert(appdata_t IN)
             {
                 v2f OUT;
                 OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
                 OUT.texcoord = IN.texcoord;
 #ifdef UNITY_HALF_TEXEL_OFFSET
                 OUT.vertex.xy += (_ScreenParams.zw-1.0)*float2(-1,1);
 #endif
                 OUT.color = IN.color * _Color;
                 return OUT;
             }

             sampler2D _MainTex;

             fixed4 frag(v2f IN) : SV_Target
             {
                 half4 color = tex2D(_MainTex, IN.texcoord) * IN.color;
                 clip (color.a - 0.01);
                 return color;
             }
         ENDCG
         }
     }
 }

功劳归于http://answers.unity3d.com/questions/878667/world-space-canvas-on-top-of-everything.html

Answer 2

我会说；设置 RenderTexture 并使 your/the UI 成为唯一绘制在其上的东西，然后将 RenderTexture 粘贴到您世界中的其他东西上

Unity 中 Google Cardboard 的 VR GUI

GUI in VR for Google Cardboard in Unity

c#

unity3d

google-cardboard

virtual-reality