处理中点到直线的正交投影？

Question

我的加工草图中有一条线段和一个圆。我想要圆的中心点 q 在线段上找到最近的点 p 并且圆将向它移动。我不太确定如何对此进行编码（正在处理中），所以任何建议都会很棒！谢谢！到目前为止，这是我的代码：

int xPos1 = 200;
int yPos1 = 200;
int xp1 = 50;
int yp1 = 50;
int xp2 = 350;
int yp2 = 50;

void setup() {
    size(400, 400); 
    strokeWeight(2);
    line(xp1, yp1, xp2, yp2);
    strokeWeight(1);
}

void draw() {
    drawCircle();
}

void drawCircle() {
    fill(50, 120, 120);
    //circle
    ellipse(xPos1, yPos1, 75, 75); 
    //circle center
    ellipse(xPos1, yPos1, 7, 7);  
    fill(255);
    text("Q", xPos1 + 15, yPos1 + 5);
    fill(50, 120, 120);
}

Answer 1

点到直线的投影如下：

从 x = a + t * n 形式的直线和一个点 p 开始。

代表直线上距离点p最近点的向量分量为：

(a - p) - ((a - p) 点 n)n

所以我们有：p + (a - p) - ((a - p) 点 n)n

经过一些简化我们有： a - ((a - p) 点 n)n

注意，((a - p) dot n) n是表示从最近点到起点沿线的位置的向量分量（即从最近点到p回到a）

让我们使用 PVectors 让生活更轻松一些。

PVector p = new PVector(200, 200);
PVector a = new PVector(50, 50);
PVector b = new PVector(350, 50);
PVector n = new PVector(350, 50); // |p2 - p1|

void setup() {
    size(400, 400); 
    strokeWeight(2);
    strokeWeight(1);

    // initialize our normalized (unit length) line direction
    n.sub(a);
    n.normalize();
}

void draw() {
    drawCircle();
}

PVector getNearestPointOnLine(PVector p, PVector a, PVector n){
    // the notation turns the computation inside out,
    // but this is equivalent to the above equation
    PVector q = PVector.mult(n, -PVector.sub(a, p).dot(n));
    q.add(a);
    return q;
}

void drawCircle() {
    // lets draw everything here where we can see it
    background(255, 255, 255);
    line(a.x, a.y, b.x, b.y);

    fill(50, 120, 120);
    //circle

    // NOTE: this may require hooking up a mouse move event handler
    p.x = mouseX;
    p.y = mouseY;
    PVector q = getNearestPointOnLine(p, a, n);

    ellipse(q.x, q.y, 75, 75); 
    //circle center
    ellipse(q.x, q.y, 7, 7);  
    fill(0); // make text visible on white background
    text("Q", q.x + 15, q.y + 5);
    //fill(50, 120, 120);
}

参考：https://en.wikipedia.org/wiki/Distance_from_a_point_to_a_line#Vector_formulation

处理中点到直线的正交投影？

Orthogonal projection of a point onto a line in processing?

java

math

vector

processing

orthogonal