Excel -（数组公式）对具有差异的多个条件求和

Question

我需要了解如何（通过数组公式）根据多个条件汇总结果。我知道有很多关于这个主题的问题已经得到解答，但我的似乎有所不同，所以据我所知，给出的解决方案并不奏效。

举个例子，见下面table。我想要做的是在同一天没有类型 C 的情况下对类型 A 的所有 Val 求和。（即第 5 天和第 7 天）

Day     Type    Val
1       A       5
1       B       6
1       C       9
2       B       2
2       A       8
2       C       3
3       C       4
3       B       2
3       A       2
4       A       5
4       B       9
4       C       8
5       A       7
5       B       5
6       A       6
6       B       3
6       C       4
7       A       7
7       B       9

Answer 1

J2中的1个元胞数组公式为：

=SUM((B2:B20="A")*C2:C20*ISERROR(MATCH(A2:A20,IF(A2:A20&B2:B20=A2:A20&"C",A2:A20),0)))

为了了解发生了什么，我使用辅助列创建了 I2 公式。 “_S1”、“_S2”和“_S3”是 headers.

下方的命名范围

I2是正规公式

=SUMPRODUCT(_S1,_S3)

_S1为数组公式

=(B2:B20="A")*C2:C20

这里我只是 return 类型 "A" 的值和其他一切的零值。

_S2为数组公式

=IF(A2:A20&B2:B20=A2:A20&"C",A2:A20)

我在这里创建了一个日期范围，其中有一个 "C" 和一些额外的 FALSE。

_S3为数组公式

=ISERROR(MATCH(A2:A20,_S2,0))*1

在这里，我尝试将 A 列中的一天匹配到范围 _S2 中的 'C-days'。如果有匹配我return0，否则1.

Answer 2

我可以提供这个很酷的公式的稍微简化的版本吗？

=SUM((B2:B20="A")*C2:C20*ISERROR(MATCH(A2:A20,(B2:B20="C")*A2:A20,0)))

Excel -（数组公式）对具有差异的多个条件求和

Excel - (Array Formula) Sum IF Multiple Criteria with a Difference

excel

sum

array-formulas