在 Perl 中将所有参数作为字符串传递给子例程

Question

我正在尝试编写一个函数，该函数可以获取所有参数并将它们打印为与输入的字符串完全相同的字符串。

例如使用以下函数：

test('arg1' => $arg1, 'arg2' => $arg2);

我想在函数中获取以下字符串 格式化 EXACTLY 如下所示:

"'arg1' => $arg1, 'arg2' => $arg2"

我想这样做，这样我就可以按照为 debugging/testing 目的输入的相同方式打印所有参数。

Answer 1

我知道这可能不是最好的解决方案，但它有效：

sub test {
    my (undef, $file_name, $line_number) = caller;
    open my $fh, '<', $file_name or die $!;
    my @lines = <$fh>;
    close $fh;

    my $line = $lines[$line_number - 1];
    trim($line);

    print $line."\n";
}

sub trim {
    return map { $_ =~ s/^\s+|\s+$//g } @_;
}

现在当你运行这个：

test(time);

你会得到这样的输出：

test(time);

Answer 2

Perl 提供了特殊的 debugging hooks 让你看到编译源文件的原始行。您可以编写自定义调试器，在每次调用子例程时打印原始行。

下面可以让你指定一个或多个你要匹配的子程序；每次调用匹配的子例程时，都会打印相应的行。

package Devel::ShowCalls;

our %targets;

sub import {
    my $self = shift;

    for (@_) {
        # Prepend 'main::' for names without a package specifier
        $_ = "main::$_" unless /::/;
        $targets{$_} = 1;        
    }
}

package DB;

sub DB {
    ($package, $file, $line) = caller;
}

sub sub {
    print ">> $file:$line: ",
          ${ $main::{"_<$file"} }[$line] if $Devel::ShowCalls::targets{$sub};
    &$sub;
}

1;

跟踪以下程序中函数 foo 和 Baz::qux 的调用：

sub foo {}
sub bar {}
sub Baz::qux {}

foo(now => time);
bar rand;
Baz::qux( qw/unicorn pony waffles/ );

运行:

$ perl -d:ShowCalls=foo,Baz::qux myscript.pl 
>> myscript.pl:5: foo(now => time);
>> myscript.pl:7: Baz::qux( qw/unicorn pony waffles/ );

请注意，这只会打印调用的第一行，因此它不适用于像

这样的调用

foo( bar,
     baz );

在 Perl 中将所有参数作为字符串传递给子例程

Getting all arguments passed to a subroutine as a string in Perl

string

perl

arguments

parameter-passing

subroutine