如何将公式翻译成 TLA+ 代码

Question

我写了汉诺塔问题的 TLA+ 规范：

TEX

ASCII

------------------------------- MODULE Hanoi -------------------------------

EXTENDS Sequences, Integers
VARIABLE A, B, C


CanMove(x,y) == /\ Len(x) > 0 
                /\ IF Len(y) > 0 THEN Head(y) > Head(x) ELSE TRUE

Move(x,y,z) == /\ CanMove(x,y)
               /\ x' = Tail(x)
               /\ y' = <<Head(x)>> \o y
               /\ z' = z

Invariant == C /= <<1,2,3>>   \* When we win!                           

Init == /\ A = <<1,2,3>>
        /\ B = <<>>
        /\ C = <<>>

Next == \/ Move(A,B,C) \* Move A to B
        \/ Move(A,C,B) \* Move A to C
        \/ Move(B,A,C) \* Move B to A
        \/ Move(B,C,A) \* Move B to C
        \/ Move(C,A,B) \* Move C to A
        \/ Move(C,B,A) \* Move C to B
=============================================================================

当我将 Invariant 公式指定为不变量时，TLA 模型检查器将为我解决这个难题。

不过我想让它不那么冗长，理想情况下我不想将未更改的变量传递给 Move()，但我不知道该怎么做。我想做的是写

Move(x,y) == /\ CanMove(x,y)
             /\ x' = Tail(x)
             /\ y' = <<Head(x)>> \o y
             /\ UNCHANGED (Difference of and {A,B,C} and {y,x})

如何用 TLA 语言表达？

Answer 1

您应该使用单个序列 towers 而不是变量 A、B、C，其中塔是索引。这也将具有塔数通用的优势。您的 Next 公式也会更短：

CanMove(i,j) == /\ Len(towers[i]) > 0 
                /\ Len(towers[j]) = 0 \/ Head(towers[j]) > Head(towers[i])

Move(i, j) == /\ CanMove(i, j)
              /\ towers' = [towers EXCEPT ![i] = Tail(@),
                                          ![j] = <<Head(towers[i])>> \o @]

Init == towers = << <<1,2,3>>, <<>>, <<>> >> \* Or something more generic

Next == \E i, j \in DOMAIN towers: i /= j /\ Move(i, j)

或者，如果你想继续使用字母，你可以使用记录而不是 towers 的序列，你需要在我建议的规范中更改的是：

Init == towers = [a |-> <<1, 2, 3>>, b |-> <<>>, c |-> <<>>]

如何将公式翻译成 TLA+ 代码

How to translate formula into TLA+ code

tla+