你如何使用 Stratio Cassandra Lucene Index 进行小写前缀过滤

Question

是否可以使用 Stratio Cassandra Lucene 索引做小写前缀 filtering/querying？我无法找到有关此特定用例的文档。

Answer 1

查询的大小写取决于Lucene text analyzer在建立索引时的工作量，不能在查询时决定。如果你想进行不区分大小写的前缀搜索，你应该使用一个映射器和一个生成小写术语的分析器。这些术语将在搜索时被索引和匹配。例如：

CREATE KEYSPACE test
WITH REPLICATION = {'class' : 'SimpleStrategy', 'replication_factor': 1};
USE test;
CREATE TABLE test (
    id INT PRIMARY KEY,
    body TEXT
);

CREATE CUSTOM INDEX test_index ON test ()
USING 'com.stratio.cassandra.lucene.Index'
WITH OPTIONS = {
    'refresh_seconds' : '1',
    'schema' : '{
        fields : {
            body1 : {type :"string", column:"body", case_sensitive:false},
            body2 : {type :"string", column:"body", case_sensitive:true}
        }
    }'
};

INSERT INTO test(id,body) VALUES ( 1, 'foo');
INSERT INTO test(id,body) VALUES ( 2, 'Foo');
INSERT INTO test(id,body) VALUES ( 3, 'bar');
INSERT INTO test(id,body) VALUES ( 4, 'Bar');


SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body2", value:"f"}}'); -- Returns foo
SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body2", value:"F"}}'); -- Returns Foo

SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body1", value:"f"}}'); -- Returns foo and Foo
SELECT * FROM test WHERE expr(test_index, 
   '{filter:{type:"prefix", field:"body1", value:"F"}}'); -- Returns no results

你如何使用 Stratio Cassandra Lucene Index 进行小写前缀过滤

How do you do lowercase prefix filtering with Stratio Cassandra Lucene Index

lucene

cassandra

stratio

cassandra-lucene-index