marklogic 8 - 如何明智地搜索集合

Question

我已经在我的查询控制台中尝试了下面提到的 Xquery，但我需要从 collections 明智地搜索数据？

let $value1 := "antony"
let $value2 := "cse"
for $uri1 in cts:uris((),(), (  
    cts:element-query(xs:QName("P"),
      cts:and-query((
          cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),$value1),
          cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),$value2)
      ))
    )
))
let $xml := doc($uri1)
return $xml//PS/P [@name eq "volume"]/@value

请建议我如何在上述 XQuery 中添加集合？

Answer 1

首先我要说的是，既然你最终想要的是文档而不是 URI，那么直接使用 cts:search 会更有效。如果你想避免过滤成本，你可以添加 "unfiltered" 选项，例如：

let $value1  := "antony"
let $value2 := "cse"
return
cts:search( doc(), 
  cts:element-query(xs:QName("P"),
    cts:and-query((
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),$value1),
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),$value2)
    ))
  ), "unfiltered"
)//PS/P[@name eq "volume"]/@value

或者，因为您只关心 /PS/P 个元素：

cts:search( doc()//PS/P, 
  cts:element-query(xs:QName("P"),
    cts:and-query((
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),"antony"),
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),"cse")
    ))
  ), "unfiltered"
)[@name eq "volume"]/@value

要在集合中搜索，请将 doc() 替换为 collection("yourcollection"):

cts:search( collection("yourcollection")//PS/P, 
  cts:element-query(xs:QName("P"),
    cts:and-query((
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),"antony"),
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),"cse")
    ))
  ), "unfiltered"
)[@name eq "volume"]/@value

marklogic 8 - 如何明智地搜索集合

marklogic 8 - How to search collection wise

xquery

marklogic

marklogic-8