在 AppleScript 中选择弹出菜单按钮

Question

我想自动点击特定的下拉菜单项。例如，我想将 "Message receive Sound" 的值更改为其他值。我如何使用 AppleScript 执行此操作？我如何使用 AppleScript 中的其他弹出式菜单执行此操作？

（要打开 iMessage 设置菜单，如图所示，在打开 iMessage 后键入 CMD COMMA）

注意：我已经成功完成了这个Automator，我只是想在applescript中完成。

Answer 1

这叫做 GUI 脚本。您必须确定对 UI 元素的引用。

GUI 脚本强烈依赖于系统版本。如果更新更改了 UI 结构，脚本将中断。

这会在声音弹出菜单中选择声音 "Popcorn"。这是给埃尔卡皮坦的。在小于 10.11 的系统中，UI 元素可能不同，进程名称可能是 "iChat"

tell application "System Events"
    tell process "Messages"
        set frontmost to true
        if not (exists (1st window whose value of attribute "AXIdentifier" is "MessagesPreferencesWindow")) then
            keystroke "," using command down
            repeat until exists (1st window whose value of attribute "AXIdentifier" is "MessagesPreferencesWindow")
                delay 0.1
            end repeat
        end if
        tell (1st window whose value of attribute "AXIdentifier" is "MessagesPreferencesWindow")
            tell pop up button 4 of group 1
                click
                delay 0.2
                click menu item "Popcorn" of menu 1
            end tell
        end tell
    end tell
end tell

在 AppleScript 中选择弹出菜单按钮

Selecting Pop Up Menu Buttons in AppleScript

user-interface

applescript

imessage